Workflow ECC 6.0 error

Question

Hi all,
we have created a custom workflow and the workflow called in F110 tcode. in F110 we add on button for triggering workflow. in 4.7 it's working fine.
but in ECC 6.0 we have got an error.
ERROR :
1. The calling of the object method for the work item ended with a return value for which no handling is modeled in the workflow.
Executing batch work item Work item 000000703305: Object ZBUSF110 method ZWF_SEGGREGATE_US_UNAME cannot be executed WF-BATCH 06/25/2008 - 15:00:50
EXECUTE_METHOD_OBJECT_SYNC The source and target structure have a different number of fields WF-BATCH 06/25/2008 - 15:00:50
EXECUTE_METHOD_BOR The source and target structure have a different number of fields WF-BATCH 06/25/2008 - 15:00:50
IMPORT_FROM_BOR_CONTAINER The source and target structure have a different number of fields WF-BATCH 06/25/2008 - 15:00:50
thanks

Answer 1

The below program will help you identify if there are any container elements that are referring to undefined Data Dictionary types:
*& Report  ZBC_CHECK_CONTAINER_ELEMENTS
*& Written by Edwin Vleeshouwers
*& Reason: When upgrading from 4.6C to ECC 6.0, workflows may cause
*&         problems. If an element in the workflow is referring to a
*&         Data Dictionary element that is no longer existing, the
*&         workflow builder will not be accessible. Also the workflow
*&         will fail.
*& Correction measures and tools:
*& 1. Identify the customer workflows which have elements that refer
*&    to undefined elements.
*& 2. EITHER: Add the deleted element to the dictionary again.
*&    Then correct the workflow (you can now enter the workflow builder).
*&    Then delete the dictionary element again,
*&    OR: use program RSWF_CNT_BOR_ELEM_REPLACE to replace the
*&    references to ZTABLE-VKORG with TVKO-VKORG (for example).
*&    But, make sure that the type is the same.
*& Please note:
*& The program reads the container elements from table SWDSWFCONT.
*& In the new SAP release this table is no longer used. Instead,
*& table SWDSCONT is used. So there might be newer versions in your
*& system (created in ECC6.0).
*& But this is not a problem. We just need to find out which elements
*& were used in the 4.6C version of the workflow. These need to be
*& replaced with correct data dictionary elements that actually exist.
REPORT zbc_check_container_elements.
DATA: swdswfcont TYPE swdswfcont.
DATA: ta_swdswfcont    TYPE STANDARD TABLE OF swdswfcont.
DATA: wa_swdswfcont    TYPE swdswfcont.
DATA: wa_newer_version TYPE swdswfcont.
DATA: wa_dd03l         TYPE dd03l.
DATA: z_error          TYPE char1.
DATA: tp_text          TYPE char255.
DATA: ltp_tabix        TYPE sy-tabix.
DATA: ltp_fromindex    TYPE sy-tabix.
SELECT-OPTIONS: so_wfdid FOR swdswfcont-wfd_id.
START-OF-SELECTION.
* Select old definitions:
  SELECT *
         FROM swdswfcont
         INTO TABLE ta_swdswfcont
         WHERE wfd_id    IN so_wfdid
         AND   refstruct <> space
         AND   reffield  <> space
         AND   refstruct <> 'SY'
         AND   reftype   = 'D'
         AND   version   <> '9999'.
END-OF-SELECTION.
  SORT ta_swdswfcont BY wfd_id  ASCENDING
                        version ASCENDING.
* Delete all versions except the last:
  LOOP AT ta_swdswfcont INTO wa_swdswfcont.
    ltp_tabix = sy-tabix.
    ltp_fromindex = sy-tabix + 1.
    LOOP AT ta_swdswfcont INTO wa_newer_version
                                FROM ltp_fromindex
                                WHERE wfd_id  = wa_swdswfcont-wfd_id
                                AND   element = wa_swdswfcont-element.
      IF sy-subrc = 0.
        DELETE ta_swdswfcont where wfd_id  = wa_swdswfcont-wfd_id
                             and   version = wa_swdswfcont-version.
        EXIT.
      ENDIF.
    ENDLOOP.
  ENDLOOP.
* Now check:
  LOOP AT ta_swdswfcont INTO wa_swdswfcont.
    SELECT SINGLE * FROM dd03l INTO  wa_dd03l
                               WHERE tabname =   wa_swdswfcont-refstruct
                               AND   fieldname = wa_swdswfcont-reffield.
    IF sy-subrc <> 0.
      CONCATENATE '|'
                  'Incorrect reference in Workflow:' wa_swdswfcont-wfd_id '|'
                  'Version:' wa_swdswfcont-version '|'
                  'Container element:' wa_swdswfcont-element
                  'refers to Table:' wa_swdswfcont-refstruct
                  'Field:' wa_swdswfcont-reffield
                  INTO tp_text
                  SEPARATED BY space.
      WRITE: / tp_text.
      z_error = 'X'.
    ENDIF.
  ENDLOOP.
  IF z_error = 'X'.
    WRITE: / sy-uline.
    WRITE: / 'Please note that there may be newer versions already.', 'Errors may already have been corrected.'.
    WRITE: / 'The data represented here is as it was in 4.6C.', 'It allows you to check if there were elements used in 4.6C'.
    WRITE: / 'that referred to undefined Data Dictionary elements'.
    WRITE: / sy-uline.
    WRITE: / 'CORRECT with program RSWF_CNT_BOR_ELEM_REPLACE (note 939489)'.
    WRITE: / sy-uline.
  ENDIF.