WRAPPING TEXT

Question

Hi:
Does anyone know if I can find somewhere code to cause long lines to properly wrap at x number of chars. For instance if I had a character field that captures comments and those comments can be 2000 characters long, I would like to separate the text into lines of 80 characters each, wrapped at word boundaries.
Thanks,
Thomas

Answer 1

Not sure how this is a Forms situation, but it just so happens that yesterday I was fooling around with a pl/sql procedure to wordwrap lines. Hope it helps:
Declare
  txt varchar2(2000)
   := 'This is some text to test the "wordwrap" line break procedure.  '
   || 'The procedure will format the input text, breaking at the last '
   || 'space found nearest to the end of the text line.  The resulting '
   || 'output text will be multiple lines of nearly equal length.  '
   || 'The procedure accepts two input variables:  the text string, and '
   || 'the line length.  It outputs a pl/sql table with the formatted '
   || 'lines.  Note that all the input text should have a space at the '
   || 'end of each word, and two spaces after the end-of-sentence '
   || 'period (except for the last sentence.)';
  TYPE      txt_tbl_typ IS TABLE OF VARCHAR2(100) INDEX BY BINARY_INTEGER;
  txt_tbl   txt_tbl_typ;
PROCEDURE wordwrap
  (msg       IN  VARCHAR2,
   max_i     IN  NUMBER,
   txt_tbl_o OUT txt_tbl_typ)
IS
  P      PLS_INTEGER := 1;
  L      PLS_INTEGER := NVL(LENGTH(msg),0);
  Sp     PLS_INTEGER;
  maxlen PLS_INTEGER := GREATEST(LEAST(max_i,100),10);
BEGIN
  Txt_tbl_o.DELETE;
  LOOP
    -- skip forward to first non-blank character
    LOOP
      EXIT WHEN P > L OR SUBSTR(msg,P,1) <> ' ';
      P := P + 1;
    END LOOP;
    EXIT WHEN P > L;
    IF P + maxlen > L then
      -- Last line --
      txt_tbl_o( NVL(txt_tbl_o.LAST,0) + 1 ) := RTRIM(SUBSTR(msg,P));
      P := L + 1;
    ELSE
      -- break on space
      Sp := INSTR(SUBSTR(msg,P,maxlen+1),' ',-1) + P - 1;
      If Sp - P <= 0 then --no space found so output full length
        txt_tbl_o( NVL(txt_tbl_o.LAST,0) + 1 ) := SUBSTR(msg,p,maxlen);
        P := P + maxlen;
      ELSE
        -- no space, just print full line --
        txt_tbl_o( NVL(txt_tbl_o.LAST,0) + 1 ) := RTRIM(SUBSTR(msg,P,Sp-P));
        P := Sp;
      END IF;
    END IF;
  END LOOP;
END wordwrap;
-- This process below tests wordwrap.  You can change the second
-- parameter to any length between 10 and 100.
BEGIN
  wordwrap(txt,50,txt_tbl);
  FOR i in 1..txt_tbl.LAST LOOP
    DBMS_OUTPUT.PUT_LINE(txt_tbl(i));
  END LOOP;
END;