Is there a plugin or utility that converts .pages to and from LaTeX?

Question

If not, how do we ask Apple for this sort of functionality as an enhancement request? Pages is a nice neat editing and authoring tool. I'd love for it to be extensible, and enable it to save in open formats. RTF is not an open format, by the way. M$ keep changing its behaviour.
Also: XHTML would be nice.

Answer 1

Hey there, this question is similar to this one. I provided a one-way solution with AppleScript from Pages > LaTeX. See original post for details.
TeXify Pages Script:
-- Creates new file on desktop to preserve original
tell application "Pages"
    set desktopPath to path to desktop folder as text
    set docName to (name of document 1) & "_texified.pages"
    tell application "System Events"
        if exists alias (desktopPath & docName) then delete alias (desktopPath & docName)
        make new file at end of folder desktopPath with properties {name:docName}
    end tell
    save document 1 in alias (desktopPath & docName)
    open (desktopPath & docName)
end tell
-- This is the actual part that does what I call "Texifying"
tell application "Pages"
    tell document 1
        get properties
        set {xpath, xname, xbodytext, paraCount} to {path, name, body text, get count of paragraphs}
        set paraSection to {"Section", "Subsection", "Subsubsection"}
        set paraInline to {"Paragraph"}
        repeat with paraStep from 1 to paraCount
            set paraStyle to name of paragraph style of paragraph paraStep
            set paraContent to text of paragraph paraStep
            if paraStyle is in paraSection then
                if (paraContent as string) does not contain "{" then
                    if paraStyle is "Section" then
                        my texifyHeading(paraContent, paraStyle, "Section", paraStep)
                    end if
                    if paraStyle is "Subsection" then
                        my texifyHeading(paraContent, paraStyle, "Subsection", paraStep)
                    end if
                    if paraStyle is "Subsubsection" then
                        my texifyHeading(paraContent, paraStyle, "Subsubsection", paraStep)
                    end if
                end if
            end if
        end repeat
        set orig_wordCount to count of words
        repeat with wordStep from 1 to orig_wordCount
            set new_wordCount to (count of words) --gets recalculated with each step
            set wordCompensator to (new_wordCount - orig_wordCount)
            set wordContent to text of word (wordStep + wordCompensator)
            set wordProps to properties of word (wordStep + wordCompensator)
            set charOffset to character offset of word (wordStep + wordCompensator)
            set preChar to character (charOffset - 1)
            set duppreventionList to {"\\", "{", "}"}
            if preChar is not in duppreventionList then
                if name of paragraph style of wordProps is not in paraSection then
                    if bold of wordProps is true then
                        my replaceWord(wordContent, "textbf", (wordStep + wordCompensator))
                        set wordCompensator to wordCompensator + 1
                    end if
                    if italic of wordProps is true then
                        my replaceWord(wordContent, "emph", (wordStep + wordCompensator))
                        set wordCompensator to wordCompensator + 1
                    end if
                end if
            end if
        end repeat
    end tell
end tell
on replaceWord(word_content, tex_style, word_num)
    tell application "Pages"
        tell document 1
            set text of word word_num to "\\" & tex_style & "{" & word_content & "}"
        end tell
    end tell
end replaceWord
on texifyHeading(para_content, pages_style, tex_style, para_num)
    set paraSection to {"Section", "Subsection", "Subsubsection"}
    set paraInline to {"Paragraph"}
    set sedFix to do shell script "echo " & para_content & "| sed \"s/$(printf '\r')\\$//\""
    tell application "Pages"
        tell document 1
            --if first character of (para_content as string) is not "\\" then
            --if tex_style is in paraSection then
            try
                if last character of (para_content as string) is (ASCII character 13) then
                    set returnText to "\\" & tex_style & "{" & sedFix & "}" & "\r"
                else
                    set returnText to "\\" & tex_style & "{" & para_content & "}"
                end if
                set text of paragraph para_num to returnText
                set paragraph style of paragraph para_num to pages_style
                --end if
            end try
        end tell
    end tell
end texifyHeading