QuickTime Player - Partial Screen Recording?

Question

Hello everyone,
My idea was to use AppleScript to:
- Launch Quicktime Player
-- Start Screen Recording
-- Check that 'Show Mouse Click in Recording' is marked
-- Click 'Record' button
--- Let user drag his desired portion of the screen
--- Start record
--- Stop record
-- Save movie
- Close QuickTime Player
So far I only got to the point where the user needs to 'drag his desired portion of the screen'.
But I also have a problem detecting that 'Show Mouse Click in Recording' is checked or not.
I can click it, but if it's already checked - it'll just go off. The problem is that it's not really a checkbox element rather a menu item.
Is there a way around it?
Also, and more important, how can I tell when the user finished his recording I.e. clicks the 'Stop' button so the script
can move on to saving that file.
Here is what I got so far (pretty basic):
tell application "QuickTime Player"
activate
end tell
tell application "System Events"
          tell process "QuickTime Player"
                    click menu item "New Screen Recording" of menu "File" of menu bar 1
                    click menu button of window "Screen Recording"
                    click menu item "Show Mouse Clicks in Recording" of menu 1 of menu button 1 of window "Screen Recording"
                    click button 1 of window "Screen Recording"
          end tell
end tell
So, am I crazy or is it possible?
I am pretty new to AppleScript, if there is a different, better way to do it, I would love to know.
Thanks!
Mac OSX 10.8.5
QuickTime Player 10.2

Answer 1

I don't know much about QuickTime Player. Nevertheless, maybe the following script, tested with QuickTime Player 10.3 under OS X 10.9.1, can help you.
tell application "QuickTime Player"
    set theDocument to new screen recording
    activate
end tell
tell application "System Events"
    tell process "QuickTime Player"
        tell menu button 1 of window "Screen Recording"
            click
            tell menu item "Show Mouse Clicks in Recording" of menu 1
                if value of attribute "AXMenuItemMarkChar" is missing value then
                    click
                else
                    keystroke return
                end if
            end tell
        end tell
        click button 1 of window "Screen Recording"
        repeat until exists menu bar item 1 of menu bar 2
            delay 1
        end repeat
        repeat while exists menu bar item 1 of menu bar 2
            delay 1
        end repeat
        repeat until exists window "Untitled"
            delay 1
        end repeat
        click menu item "Save…" of menu 1 of menu bar item "File" of menu bar 1
    end tell
end tell