Standard ABAP functions for creating events?

Question

Hi,
I'm a little bit confused which ABAP functions to use for creating academic events with schedules (e.g. lecture takes places each Friday at 4 pm), rooms and instructors attached.
Data transfer documentation SAP team recently released ("SLCM Data Transfer" archive, "Intro" document, page 18) suggests <b>HRIQ_CREATE_EVENT</b> as a solution. However, after experimenting for a while, I noticed a note attached to this function that "DO NOT USE ANYMORE, USE <b>HRIQ_EVENT_CREATE</b>".
So which one is the correct/recommended one? Also, if possible, I would prefer an RFC-enabled one.
Thanks
Janek

Answer 1

Hi Janek,
We've created a custom RFC enabled function module to wrap the SAP function module HRIQ_CREATE_EVENT in.  We are on a 4.7 system.  Here is our code.  Hope it helps.
FUNCTION zcep_event_create .
*"*"Local interface:
*"  IMPORTING
*"     VALUE(VTASK) TYPE  HRRHAP-VTASK DEFAULT 'V'
*"     VALUE(EVENTPACKAGEID) TYPE  HROBJID
*"     VALUE(ACAD_YEAR) TYPE  PIQPERYR
*"     VALUE(ACAD_SESSION) TYPE  PIQPERID
*"  TABLES
*"      MEETING_PATTERN STRUCTURE  ZCEP_MEETINGPATTERN
*"      EVENT STRUCTURE  ZCEP_EVENT
*"      RETURN STRUCTURE  BAPIRET2
  DATA: is_schedule TYPE bapisched,
        schedule TYPE bapisched OCCURS 0 WITH HEADER LINE,
        capacity LIKE hri1024,
        wa_capacity LIKE hri1024 OCCURS 0 WITH HEADER LINE,
        location LIKE bapilocdat-locid OCCURS 0,
        new_event_package LIKE p1000 OCCURS 0 WITH HEADER LINE,
        objid  LIKE hrrootob OCCURS 0 WITH HEADER LINE,
        parent LIKE hrhctobjc OCCURS 0 WITH HEADER LINE,
        eventid TYPE hrobjid,
        event_id_out LIKE bapievdat-eveid,
        lt_1739 TYPE TABLE OF p1739,
        ls_1739 TYPE p1739,
        ls_error_record TYPE bapiret2,
        ls_nnnn TYPE wplog,
        open_resources_exits TYPE xfeld.
  DATA:  it_1035 TYPE piq_p1035_t,
         it_pt_1035t TYPE piq_hrt1035_t,
         it_daysoff TYPE piq_pt1035_t,
         it_daysfree TYPE piq_pt1035_t,
         ls_daysfree TYPE pt1035,
         ls_1035t TYPE hrt1035.
  DATA: it_bapiresou TYPE TABLE OF bapiresou,
        is_bapiresou TYPE bapiresou,
        resources TYPE bapiresou OCCURS 0.
  DATA: it_pa0002 TYPE TABLE OF pa0002,
        is_pa0002 TYPE pa0002,
        it_hrp1000 TYPE TABLE OF hrp1000,
        is_hrp1000 TYPE hrp1000,
        lv_dayoff(1),
        bp(12),
        im_begda LIKE sy-datum,
        im_endda LIKE sy-datum,
        sobid LIKE hrp1001-sobid,
        event_counted_dates TYPE dayct,
        event_counted_hours TYPE hrsct,
        ndays TYPE p1035-ndays,
        nhours TYPE p1035-nhours.
  FIELD-SYMBOLS: <ls_1035t> LIKE LINE OF it_pt_1035t.
  CLEAR gt_error_record[].
  SORT event BY short.
  SORT meeting_pattern BY eventname.
*************************  Get Calender Date  *************************
  SELECT SINGLE begda endda FROM hrt1750 INTO (im_begda,im_endda)
          WHERE peryr = acad_year
            AND perid = acad_session
            AND timelimit = '0100'.
***************************  Create Event  ****************************
  LOOP AT event.
    CLEAR resources.
    LOOP AT meeting_pattern WHERE eventname = event-short.
*********************  Create Schedule for Event  *********************
      CALL FUNCTION 'HRIQ_EVENT_SCHEDULE_BUILD'
        EXPORTING
          plvar                = '01'
          istat                = '1'
          event_begda          = event-begda
          event_endda          = event-endda
          monday               = meeting_pattern-monday
          tuesday              = meeting_pattern-tuesday
          wednesday            = meeting_pattern-wednesday
          thursday             = meeting_pattern-thursday
          friday               = meeting_pattern-friday
          saturday             = meeting_pattern-saturday
          sunday               = meeting_pattern-sunday
          event_beguz          = meeting_pattern-start_time
          event_enduz          = meeting_pattern-end_time
          frequency            = '1'
          event_location       = meeting_pattern-location
        IMPORTING
          pt_1035              = it_1035
          pt_1035t             = it_pt_1035t
          pt_daysoff           = it_daysoff
          pt_daysfree          = it_daysfree
        EXCEPTIONS
          no_date_number       = 1
          frequency_is_initial = 2
          OTHERS               = 3.
      LOOP AT it_daysfree INTO ls_daysfree.
        CALL FUNCTION 'HRIQ_CHECK_MODULOFFER_DAYSOFF'
          EXPORTING
            iv_date             = ls_daysfree-evdat
          IMPORTING
            ev_dayoff           = lv_dayoff
          EXCEPTIONS
            otype_not_supported = 0
            OTHERS              = 0.
        IF lv_dayoff = space.
          MOVE-CORRESPONDING ls_daysfree TO ls_1035t.
          APPEND ls_1035t TO it_pt_1035t.
        ENDIF.
      ENDLOOP.
* no double entries
      SORT it_pt_1035t.
      DELETE ADJACENT DUPLICATES FROM it_pt_1035t.
      DESCRIBE TABLE it_pt_1035t LINES event_counted_dates.
      CLEAR event_counted_hours.
      LOOP AT it_pt_1035t INTO ls_1035t.
        nhours = ( ls_1035t-enduz - ls_1035t-beguz ) / 3600.
        event_counted_hours = event_counted_hours + nhours.
        ADD 1 TO ndays.
      ENDLOOP.
      LOOP AT it_pt_1035t ASSIGNING <ls_1035t>.
        MOVE-CORRESPONDING <ls_1035t> TO schedule.
        APPEND schedule.
      ENDLOOP.
*Room
      IF NOT meeting_pattern-room IS INITIAL.
        SELECT SINGLE short stext FROM hrp1000
                 INTO (is_hrp1000-short,is_hrp1000-stext)
                WHERE plvar = '01'
                  AND istat = '1'
                  AND otype = 'G'
                  AND objid = meeting_pattern-room
                  AND begda LE sy-datum
                  AND endda GE sy-datum.
        SELECT SINGLE sobid FROM hrp1001 INTO sobid
                WHERE otype = 'G'
                  AND plvar = '01'
                  AND istat = '1'
                  AND relat = '020'
                  AND rsign = 'A'
                  AND sclas = 'R'
                  AND objid = meeting_pattern-room
                  AND begda LE im_endda
                  AND endda GE im_begda.
        IF sy-subrc = 0.
          is_bapiresou-retid = sobid(8).
        ENDIF.
        LOOP AT it_pt_1035t ASSIGNING <ls_1035t>.
          is_bapiresou-resht = is_hrp1000-short.
          is_bapiresou-resxt = is_hrp1000-stext.
          is_bapiresou-resbg = <ls_1035t>-evdat.
          is_bapiresou-resed = <ls_1035t>-evdat.
          is_bapiresou-beguz = meeting_pattern-start_time.
          is_bapiresou-enduz = meeting_pattern-end_time.
          is_bapiresou-resid = meeting_pattern-room.
          is_bapiresou-restp = 'G'.
          APPEND is_bapiresou TO resources.
        ENDLOOP.
      ENDIF.
* Instructor
      IF NOT meeting_pattern-instructor IS INITIAL.
        SELECT SINGLE nachn vorna FROM pa0002
                 INTO (is_pa0002-nachn, is_pa0002-vorna)
                WHERE pernr = meeting_pattern-instructor
                  AND begda LE im_endda
                  AND endda GE im_begda.
**************************  Meeting Pattern  **************************
        SELECT SINGLE objid INTO is_bapiresou-retid FROM hrp1000
                WHERE plvar = '01'
                  AND langu = 'E'
                  AND otype = 'R'
                  AND mc_short = 'INST-CM'
                  AND begda LE im_endda
                  AND endda GE im_begda.
        LOOP AT it_pt_1035t ASSIGNING <ls_1035t>.
          is_bapiresou-resht = is_pa0002-nachn.
          CONCATENATE is_pa0002-vorna is_pa0002-nachn
                 INTO is_bapiresou-resxt
            SEPARATED BY space.
          is_bapiresou-resbg = <ls_1035t>-evdat.
          is_bapiresou-resed = <ls_1035t>-evdat.
          is_bapiresou-beguz = meeting_pattern-start_time.
          is_bapiresou-enduz = meeting_pattern-end_time.
          is_bapiresou-resid = meeting_pattern-instructor.
          is_bapiresou-restp = 'P'.
          APPEND is_bapiresou TO resources.
        ENDLOOP.
      ENDIF.
    ENDLOOP.
    wa_capacity-kapz1 = event-mincapty.
    wa_capacity-kapz2 = event-optcapty.
    wa_capacity-kapz3 = event-maxcapty.
    capacity = wa_capacity.
    CALL FUNCTION 'HRIQ_CREATE_EVENT'
      EXPORTING
        planversion     = '01'
        event_id_in     = '00000000'
        event_short     = event-short
        event_stext     = event-stext
        status          = '1'
        begin_date      = event-begda
        end_date        = event-endda
        language        = sy-langu
        eventtype       = event-betype
        capacity        = capacity
        location        = meeting_pattern-location
        check_resources = ' '       "'X'
        vtask           = 'B'
      IMPORTING
        event_id_out    = event_id_out
      TABLES
        schedule        = schedule
        resources       = resources
        return          = return.
    IF sy-subrc NE 0.
      CALL FUNCTION 'HRIQ_CLEAR_BUFFER'.
      CALL FUNCTION 'HRIQ_CLEAR_PLOG_TAB'.
      return-type = 'E'.
      return-message = 'Error during save'.
      APPEND return.
    ENDIF.
    LOOP AT return WHERE id = 'HRPIQ000'
                     AND number = '846'.
      return-type = 'E'.
      return-message = 'Resources already in use'.
      APPEND return.
      EXIT.
    ENDLOOP.
**********************  Create Session offering  **********************
    MOVE-CORRESPONDING ls_nnnn TO ls_1739.
    ls_1739-mandt = sy-mandt.
    ls_1739-plvar = '01'.
    ls_1739-otype = 'E'.
    ls_1739-objid = event_id_out.
    ls_1739-istat = '1'.
    ls_1739-begda = event-begda.
    ls_1739-endda = event-endda.
    ls_1739-aedtm = sy-datum.
    ls_1739-uname = sy-uname.
    ls_1739-infty = '1739'.
    ls_1739-peryr = acad_year.
    ls_1739-perid = acad_session.
    APPEND ls_1739 TO lt_1739.
    PERFORM create_infotype USING lt_1739
                         CHANGING ls_error_record .
    APPEND ls_error_record TO return.
    READ TABLE return  WITH KEY type = 'E'.
    IF sy-subrc <> 0 AND vtask = 'V'.
      CALL FUNCTION 'HRIQ_UPDATE_DATABASE'
        EXPORTING
          vtask          = 'D'
          commit_flg     = 'X'
        EXCEPTIONS
          corr_exit      = 1
          internal_error = 2
          OTHERS         = 3.
      IF sy-subrc NE 0.
        CALL FUNCTION 'HRIQ_CLEAR_BUFFER'.
        CALL FUNCTION 'HRIQ_CLEAR_PLOG_TAB'.
        return-message = 'Error during save'.
        APPEND return.
      ENDIF.
    ELSE.
      CALL FUNCTION 'HRIQ_CLEAR_BUFFER'.
      CALL FUNCTION 'HRIQ_CLEAR_PLOG_TAB'.
      EXIT.
    ENDIF.
*********************  Create Relationship(E-SE)  *********************
    parent-objid = event_id_out.
    parent-otype = 'E'.
    APPEND parent.
    PERFORM create_relation TABLES parent
                             USING 'B512'
                                   'SE'
                                   event-begda
                                   event-endda
                                   eventpackageid
                          CHANGING ls_error_record.
  ENDLOOP.
  IF vtask = 'V' AND ls_error_record IS INITIAL.
    PERFORM update_database CHANGING ls_error_record.
  ELSE.
    APPEND ls_error_record TO return.
    CALL FUNCTION 'HRIQ_CLEAR_BUFFER'.
    CALL FUNCTION 'HRIQ_CLEAR_PLOG_TAB'.
  ENDIF.
  DELETE return WHERE type IS INITIAL.
ENDFUNCTION.