Working with random numbers and probabilities

Question

Hi again,
i am working with random numbers at the moment.
in the first step i do create a random number between 3 and 8 which is stored to a variable.
set myVAR1 to random number from 3 to 8 as integer
Lets assume myVAR1 is 5
Now i want to select 5 numbers out of number pool from 1 to 8. Each number should be pickable only once.
How would i realize that ?
I guess i need some kind of pool, array and then select 5 out of this array, but i am not sure about the syntax.
In best case i would like to add probabilities to those 8 numbers in the pool.
i.e.
1 (5%),2(5%),3(20%),4(10%),5(20%),6(10%),7(15%),8(15%)
any help is heavily appreciated
best regards
fidel

Answer 1

Hello fidel,
For selecting unique numbers from given pool, try something like this.
--SCRIPT 1
(* select unique numbers from pool *)
set pool to {1, 2, 3, 4, 5, 6, 7, 8} -- number pool
set n to random number from 3 to 8 -- selection count
return {n, random(n, pool)}
on random(n, pool)
set kk to {}
repeat with i from 1 to count pool
set end of kk to i
end repeat
set rr to {}
repeat n times
set k to kk's some integer
set kk's item k to false
set end of rr to pool's item k
end repeat
return rr
end random
--END OF SCRIPT 1
For introducing selection weight of each number in the pool, you may try the below.
--SCRIPT 2
(* select unique numbers from pool with stochastic weights *)
set pool to {1, 2, 3, 4, 5, 6, 7, 8} -- number pool
set weights to {5, 5, 20, 10, 20, 10, 15, 15} -- selection weight
set n to random number from 3 to 8 -- selection count
return {n, random(n, pool, weights)}
on random(n, pool, weights)
script o
property ww : weights
property pp : {}
property kk : {}
property rr : {}
repeat with i from 1 to count pool
repeat my ww's item i times
set end of my pp to pool's item i
end repeat
end repeat
repeat with i from 1 to count my pp
set end of my kk to i
end repeat
repeat n times
set k to my kk's some integer
set end of my rr to my pp's item k
set j to 0
set i to 1
repeat with w in my ww
set j to j + w
if k > j then
set i to j + 1
else
repeat with h from i to j
set my kk's item h to false
end repeat
set i to 1
exit repeat
end if
end repeat
end repeat
return my rr's contents
end script
tell o to run
end random
--END OF SCRIPT 2
Hope this may help,
H
Message was edited by: Hiroto