9.2.0.4.0 OracleParameterCollection protection level changed so breaks code

Question

We've just installed 9.2.0.4.0 to find it breaks our code. The OracleParameterCollection class has had its access level changed which means we cannot instantiate a new OracleParameterCollection.
Is this is a bug ? Or can we create an OracleParameterColection in some other way ??
Incidentally the documention still shows the class as public.

Answer 1

It looks like you're just using OracleParameterCollection as a concrete implementation of IDataParameterCollection.
If so, since ODP no longer has a public, creatable class implementing this interface,you will have to roll your own implementation of IDataParameterCollection.
Your other option is to switch from using an IDataParameterCollection to an array of IDataParameter, or a paramarray or some such.
Anyway, were's an example in VB of a simple class implementing IDataParameterCollection.
  Public Class ParameterCollection
    Implements IDataParameterCollection
    Private params As ArrayList
    Public Sub New()
      params = New ArrayList
    End Sub
    Public Sub CopyTo(ByVal array As System.Array, ByVal index As Integer) Implements System.Collections.ICollection.CopyTo
      params.CopyTo(array, index)
    End Sub
    Public ReadOnly Property Count() As Integer Implements System.Collections.ICollection.Count
      Get
        Return params.Count
      End Get
    End Property
    Public ReadOnly Property IsSynchronized() As Boolean Implements System.Collections.ICollection.IsSynchronized
      Get
        Return params.IsSynchronized
      End Get
    End Property
    Public ReadOnly Property SyncRoot() As Object Implements System.Collections.ICollection.SyncRoot
      Get
        Return params.SyncRoot
      End Get
    End Property
    Public Function GetEnumerator() As System.Collections.IEnumerator Implements System.Collections.IEnumerable.GetEnumerator
      Return params.GetEnumerator
    End Function
    Public Function Add(ByVal value As Object) As Integer Implements System.Collections.IList.Add
      Dim p As IDataParameter = DirectCast(value, IDataParameter)
      params.Add(p)
    End Function
    Public Sub Clear() Implements System.Collections.IList.Clear
      params.Clear()
    End Sub
    Public Overloads Function Contains(ByVal value As Object) As Boolean Implements System.Collections.IList.Contains
      Return params.Contains(value)
    End Function
    Public Overloads Function IndexOf(ByVal value As Object) As Integer Implements System.Collections.IList.IndexOf
      Return params.IndexOf(value)
    End Function
    Public Sub Insert(ByVal index As Integer, ByVal value As Object) Implements System.Collections.IList.Insert
      params.Insert(index, value)
    End Sub
    Public ReadOnly Property IsFixedSize() As Boolean Implements System.Collections.IList.IsFixedSize
      Get
        Return params.IsFixedSize
      End Get
    End Property
    Public ReadOnly Property IsReadOnly() As Boolean Implements System.Collections.IList.IsReadOnly
      Get
        Return params.IsReadOnly
      End Get
    End Property
    Default Public Overloads Property Item(ByVal index As Integer) As Object Implements System.Collections.IList.Item
      Get
        Return params(index)
      End Get
      Set(ByVal Value As Object)
        params(index) = Value
      End Set
    End Property
    Public Sub Remove(ByVal value As Object) Implements System.Collections.IList.Remove
      params.Remove(value)
    End Sub
    Public Overloads Sub RemoveAt(ByVal index As Integer) Implements System.Collections.IList.RemoveAt
      params.RemoveAt(index)
    End Sub
    Public Overloads Function Contains(ByVal parameterName As String) As Boolean Implements System.Data.IDataParameterCollection.Contains
      Return (IndexOf(parameterName) <> -1)
    End Function
    Public Overloads Function IndexOf(ByVal parameterName As String) As Integer Implements System.Data.IDataParameterCollection.IndexOf
      For i As Integer = 0 To params.Count - 1
        If DirectCast(params(i), IDataParameter).ParameterName = parameterName Then
          Return i
        End If
      Next
      Return -1
    End Function
    Default Public Overloads Property Item(ByVal parameterName As String) As Object Implements System.Data.IDataParameterCollection.Item
      Get
        Dim i As Integer = IndexOf(parameterName)
        If i <> -1 Then
          Return Item(i)
        Else
          Return Nothing
        End If
      End Get
      Set(ByVal Value As Object)
        Dim i As Integer = IndexOf(parameterName)
        If i <> -1 Then
          Item(i) = Value
        Else
          Throw New Exception("Parameter not found.")
        End If
      End Set
    End Property
    Public Overloads Sub RemoveAt(ByVal parameterName As String) Implements System.Data.IDataParameterCollection.RemoveAt
      Dim i As Integer = IndexOf(parameterName)
      If i <> -1 Then
        params.RemoveAt(i)
      Else
        Throw New Exception("Parameter not found.")
      End If
    End Sub
  End Class