Add checkmark to system menu item

Question

Hello,
My aim is to add a menu item to a windows system menu to toggle a stay on top feature.
I found a nice piece of code on stack overflow to accomplish this:
Link to stackoverflow code
Here is the result in my program:
I've modified the code to keep my form on top:
Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
If m.Msg = &H112 Then
If m.WParam.ToInt32 = &H1FFF Then
Me.TopMost = IIf(Me.TopMost = True, False, True)
End If
End If
MyBase.WndProc(m)
End Sub
All I need now is to place a checkmark beside my menu item to indicate the current state.
Can someone show me the code to place/remove the checkmark, given the stackoverflow code I'm using?
Any help would be appreciated.
Rick

Answer 1

Hi,
 Here is an example you can use. I changed things around a bit to correct things. This will check the menu item when it is set to TopMost and uncheck it if it is not.
Imports System.Runtime.InteropServices
Public Class Form1
Private Const WM_SYSCOMMAND As Integer = &H112
Private Const MF_STRING As Integer = &H0
Private Const MF_CHECKED As Integer = &H8
Private Const MF_UNCHECKED As Integer = &H0
<DllImport("user32.dll", EntryPoint:="GetSystemMenu")> _
Private Shared Function GetSystemMenu(ByVal hWnd As IntPtr, <MarshalAs(UnmanagedType.Bool)> ByVal bRevert As Boolean) As IntPtr
End Function
<DllImport("user32.dll", EntryPoint:="AppendMenuW")> _
Private Shared Function AppendMenuW(ByVal hMenu As IntPtr, ByVal uFlags As UInteger, ByVal uIDNewItem As UInteger, <MarshalAs(UnmanagedType.LPWStr)> ByVal lpNewItem As String) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<DllImport("user32.dll", EntryPoint:="CheckMenuItem")> _
Private Shared Function CheckMenuItem(ByVal hMenu As IntPtr, ByVal uIDCheckItem As UInteger, ByVal uCheck As UInteger) As UInteger
End Function
Private idMenu As UInteger = &H1FFF
Private hMenu As IntPtr = IntPtr.Zero
Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
hMenu = GetSystemMenu(Me.Handle, False)
AppendMenuW(hMenu, MF_STRING, idMenu, "Stay On Top")
End Sub
Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
If m.Msg = WM_SYSCOMMAND Then
If m.WParam.ToInt32 = idMenu Then
Me.TopMost = Not Me.TopMost
If Me.TopMost Then
CheckMenuItem(hMenu, idMenu, MF_CHECKED)
Else
CheckMenuItem(hMenu, idMenu, MF_UNCHECKED)
End If
End If
End If
MyBase.WndProc(m)
End Sub
End Class
If you say it can`t be done then i`ll try it