Add double quotes (") surrounding each field in GUI_DOWNLOAD

Question

Experts,
Does anyone know if it is possible to add double quotes (") to all fields in .txt file using FM GUI_DOWNLOAD besides manually concatenate the quotes into each field before calling the FM?
For example, output need to be:
"0000123" "NAME1" "   200.00"
Any advice is greatly appreciated.
Best regards,
Minami

Answer 1

If you are interested, here is a complete solution.
report zrich_0001.
data: it001 type table of t001.
data: xt001 type t001.
data: iflatf type table of string.
data: xflatf type string.
data: filename type string.
data: field_value type string.
field-symbols: <fs>.
* Selection Screen
selection-screen begin of block b1 with frame title text-002 .
parameters: p_file type localfile default
            'C:Test.txt'.
selection-screen end of block b1.
start-of-selection.
  select * into table it001 from t001.
  loop at it001 into xt001.
    do.
      assign component sy-index of structure xt001 to <fs>.
      if sy-subrc <> 0.
        exit.
      endif.
      concatenate '"' <fs> '"' into field_value.
      if sy-index = 1.
        xflatf = field_value.
      else.
        concatenate xflatf field_value into xflatf separated by space.
      endif.
    enddo.
      append xflatf to iflatf.
  endloop.
  filename = p_file.
  call method cl_gui_frontend_services=>gui_download
         exporting
              filename                = filename
              filetype                = 'ASC'
         changing
              data_tab                = iflatf.
Regard,
Rich Heilman