Adobe: How to print the documents more than once with different data.

Question

Hi Experts,
I have a requirement to print the document of minimum 5 employee's at a time.
First we are displaying the list of employee's and then the user is provided an option to select the employee's and print their details.
A form has been created. We are able to print the document for a single employee. But now the requirement is to select multiple employee's and print their details at one time.
I am able to get the contents all the employee's in an internal table. But i am not getting to combine the contents together and print the document.
So could some one help me how to get the contents of all the selected employee's and print the document's.
Thanks.

Answer 1

I don't understand whether you want to print several different documents in a row each with  an employee or one pdf document with several employees in it.
If you want to print one document with multiple employees inside, then you have to recode your PDF to be able to handle a table containing each employee data.
If you want to print multiple pdf documents each containing one employee info, then this is done in abap. [see BC480]
i.e.
DATA:
gt_customers TYPE TABLE OF scustom,
gs_customer LIKE LINE OF gt_customers,
gt_bookings TYPE ty_bookings, "table of sbook
gt_sums TYPE flprice_t,
gv_image_url TYPE string,
gv_fm_name TYPE rs38l_fnam,
* parameters for calling the generated function module
gs_docparams TYPE sfpdocparams,
gs_outputparams TYPE sfpoutputparams,
Event START-OF-SELECTION:
* Please note that the error handling implemented here is very
* rudimentary!
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
* Get name of the generated function module
TRY.
CALL FUNCTION 'FP_FUNCTION_MODULE_NAME'
EXPORTING
i_name = pa_form
IMPORTING
e_funcname = gv_fm_name.
CATCH cx_root.
MESSAGE e004 WITH pa_form.
* No active form &1 available
ENDTRY.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
* Optional: Set output parameters
gs_outputparams-nodialog = space.
gs_outputparams-preview = 'X'.
gs_outputparams-dest = pa_prnt.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
* Open print job
CALL FUNCTION 'FP_JOB_OPEN'
CHANGING
ie_outputparams = gs_outputparams
EXCEPTIONS
OTHERS = 1.
IF sy-subrc <> 0.
MESSAGE e020.
* Form processing could not be started
ENDIF.
LOOP AT gt_customers INTO gs_customer.
* Set form language and country (->form locale)
gs_docparams-langu = pa_lang.
gs_docparams-country = pa_cntry.
PERFORM find_bookings_for_customer.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
* Now call the generated function module
CALL FUNCTION gv_fm_name
EXPORTING
/1bcdwb/docparams = gs_docparams
is_customer = gs_customer
it_bookings = gt_bookings
it_sums = gt_sums
iv_image_url = gv_image_url
iv_sending_country = pa_cntry
EXCEPTIONS
OTHERS = 1.
IF sy-subrc <> 0.
MESSAGE e021.
ENDIF.
ENDLOOP.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
* Close spool job
CALL FUNCTION 'FP_JOB_CLOSE'.
In the above pay attention to the loop.
Cheers,