Almost there with a folder & file renaming script

Question

Hi all,
I have been trying to write a script that will replace text in every file and folder from given folder, and all of its subfolders and files.
I have manage to tweek the apple supplied script to rename all files but it keeps crashing when it renames a folder. I am guessing it is because if the parent folder gets renamed all the aliases to the other folders are broken?
Can anybody please help, I'm sure this script would be of use to many people!
Here is the script as it stands now
try
tell application "Finder"
set source_folder to choose folder with prompt "Select folder to rename files in:"
end tell
end try
tell application "Finder"
display dialog "Search and replace in:" buttons {"File Names", "Folder Names", "Both"} default button 3
set the search_parameter to the button returned of the result
end tell
repeat
tell application "Finder"
display dialog "Enter text to find in the item names:" default answer "" buttons {"Cancel", "OK"} default button 2
set the search_string to the text returned of the result
if the search_string is not "" then exit repeat
end tell
end repeat
repeat
tell application "Finder"
display dialog "Enter replacement text:" default answer "" buttons {"Cancel", "OK"} default button 2
set the replacement_string to the text returned of the result
if the replacement_string contains ":" then
beep
display dialog "A file or folder name cannot contain a colon (:)." buttons {"Cancel", "OK"} default button 2
else if the replacement_string contains "/" then
beep
display dialog "A file or folder name cannot contain a forward slash (/)." buttons {"Cancel", "OK"} default button 2
else
exit repeat
end if
end tell
end repeat
tell application "Finder"
display dialog "Replace “" & the search_string & "” with “" & the replacement_string & "” in every item name?" buttons {"Cancel", "OK"} default button 2
end tell
tell application "Finder"
set a to every folder of entire contents of source_folder
repeat with aa in a
-- looping within folders of selected source folder
set aastring to aa as string
set all_files to (every file in aa)
repeat with ff in all_files
-- looping within the files for the current folder
set this_item to ff
set this_item to (this_item) as alias
set this_info to info for this_item
set the current_name to the name of this_info
set change_flag to false
if the current_name contains the search_string then
if the search_parameter is "File Names" then
set the change_flag to true
else if the search_parameter is "Both" then
set the change_flag to true
end if
if the change_flag is true then
-- replace target string using delimiters
set AppleScript's text item delimiters to the search_string
set the textitemlist to every text item of the current_name
set AppleScript's text item delimiters to the replacement_string
set the newitemname to the textitemlist as string
set AppleScript's text item delimiters to ""
my setitem_name(thisitem, newitemname)
end if
end if
end repeat
-- now we have renamed all the files lets rename the folder
set this_item to aa
set this_item to (this_item) as alias
set this_info to info for this_item
set the current_name to the name of this_info
set change_flag to false
if the current_name contains the search_string then
if the search_parameter is "Folder Names" then
set the change_flag to true
else if the search_parameter is "Both" then
set the change_flag to true
end if
if the change_flag is true then
-- replace target string using delimiters
set AppleScript's text item delimiters to the search_string
set the textitemlist to every text item of the current_name
set AppleScript's text item delimiters to the replacement_string
set the newitemname to the textitemlist as string
set AppleScript's text item delimiters to ""
my setitem_name(thisitem, newitemname)
end if
end if
end repeat
end tell
beep 2
on setitem_name(thisitem, newitemname)
tell application "Finder"
--activate
set the parentcontainerpath to (the container of this_item) as text
if not (exists item (the parentcontainerpath & newitemname)) then
try
set the name of this_item to newitemname
on error the error_message number the error_number
if the error_number is -59 then
set the error_message to "This name contains improper characters, such as a colon (:)."
else --the suggested name is too long
set the error_message to error_message -- "The name is more than 31 characters long."
end if
--beep
tell me to display dialog the error_message default answer newitemname buttons {"Cancel", "Skip", "OK"} default button 3
copy the result as list to {newitemname, button_pressed}
if the button_pressed is "Skip" then return 0
my setitem_name(thisitem, newitemname)
end try
else --the name already exists
--beep
tell me to display dialog "This name is already taken, please rename." default answer newitemname buttons {"Cancel", "Skip", "OK"} default button 3
copy the result as list to {newitemname, button_pressed}
if the button_pressed is "Skip" then return 0
my setitem_name(thisitem, newitemname)
end if
end tell
end setitemname
Message was edited by: James @ Hakoona

Answer 1

Hmmm, that script is definitely a bit old.
An alias will still refer to the same file or folder, even if renamed. Your script does not crash on my machine, but the list of folder items to rename is empty. You are doing a lot more work than you really need to - you can just tell the Finder to get a list of file or folders so you don't have to do all that looping. By the way, you do not need the Finder to display the dialogs - normally an application tell statement should just contain terminology for that application (i.e. commands specific to the application).
The following script replaces your loops through the files and folders with statements that just get all of the files or folders (or both). I also renamed the buttons so that their names/selection can be used elsewhere, such as some of the dialogs.
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #DAFFB6;
overflow: auto;"
title="this text can be pasted into the Script Editor">
set source_folder to choose folder with prompt "Select a folder to rename files in:"
display dialog "Search and replace text in the names of every:" buttons {"file", "folder", "file and folder"} default button 3
set search_parameter to button returned of the result
repeat
display dialog "Enter the text to find in " & search_parameter & " names:" default answer "" buttons {"Cancel", "OK"} default button 2
set search_string to text returned of the result
if search_string is not "" then exit repeat
end repeat
repeat
display dialog "Enter the replacement text:" default answer "" buttons {"Cancel", "OK"} default button 2
set replacement_string to text returned of the result
try
if replacement_string contains ":" then error "colon (:)."
if replacement_string contains "/" then error "forward slash (/)."
exit repeat
on error error_message
beep
display dialog "A file or folder name cannot contain a " & error_message buttons {"Cancel", "OK"} default button 2
end try
end repeat
display dialog "Replace “" & search_string & "” with “" & replacement_string & "” in every " & search_parameter & " name?" buttons {"Cancel", "OK"} default button 2
tell application "Finder"
try
if search_parameter is "file" then
set item_list to files of entire contents of source_folder
else if search_parameter is "folder" then
set item_list to folders of entire contents of source_folder
else -- both
set item_list to entire contents of source_folder
end if
on error -- no items
set item_list to {}
end try
if class of item_list is not list then set item_list to {item_list} -- single item
repeat with this_item in item_list
set current_name to the name of this_item
if current_name contains the search_string then
-- replace target string using delimiters
set AppleScript's text item delimiters to search_string
set text_item_list to text items of current_name
set AppleScript's text item delimiters to replacement_string
set new_item_name to text_item_list as text
set AppleScript's text item delimiters to ""
my set_item_name(this_item, new_item_name)
end if
end repeat
end tell
beep 2
on set_item_name(this_item, new_item_name)
tell application "Finder"
--activate
set the parent_container_path to (the container of this_item) as text
if not (exists item (the parent_container_path & new_item_name)) then
try
set the name of this_item to new_item_name
on error the error_message number the error_number
if the error_number is -59 then
set the error_message to "This name contains improper characters, such as a colon (:)."
else --the suggested name is too long
set the error_message to error_message -- "The name is more than 31 characters long."
end if
--beep
tell me to display dialog the error_message default answer new_item_name buttons {"Cancel", "Skip", "OK"} default button 3
copy the result as list to {new_item_name, button_pressed}
if the button_pressed is "Skip" then return 0
my set_item_name(this_item, new_item_name)
end try
else --the name already exists
--beep
tell me to display dialog "This name is already taken, please rename." default answer new_item_name buttons {"Cancel", "Skip", "OK"} default button 3
copy the result as list to {new_item_name, button_pressed}
if the button_pressed is "Skip" then return 0
my set_item_name(this_item, new_item_name)
end if
end tell
end set_item_name
</pre>