Applescript & Mail: fail reading from list

Question

I'm trying to write a script to mark duplicates in a mailbox by creating a list of existing message IDs and mark the ones already in the list. While it does create the correct list, duplicate IDs won't be detected. Is there a bug or is it my script?
try
tell application "Mail"
set msg_count to count of message in message viewer 1
if msg_count = 0 then
display dialog "Please select the folders you want to scan for duplicates." with icon 1 buttons {"Okay"} default button 1
else
set all_msg to (every message in message viewer 1)
set id_list to {}
set dup_count to 0
repeat with this_msg in all_msg
try
set msg_id to (content of every header of this_msg whose name is "Message-ID")
on error
set msg_id to ""
set background color of this_msg to blue
end try
if msg_id is in id_list then --problem here?
set background color of this_msg to gray
set dup_count to dup_count + 1
else if msg_id is not "" then
set the end of id_list to msg_id
end if
set msg_count to msg_count - 1
if msg_count mod 100 = 0 and msg_count > 0 then say (msg_count as string) & " messages remaining"
end repeat
--choose from list id_list
if dup_count is 0 then
say "done. no duplicates found"
else
say "done. " & dup_count & " duplicates found."
end if
end if
end tell
on error the error_message number the error_number
-- don't display error message if the user canceled a dialog within the [try] and [on error] lines above
if the error_number is not -128 then
set the error_text to "Error: " & the error_number & ". " & the error_message
display dialog the error_text buttons {"Cancel"} default button 1
else
error number -128
end if
end try

Answer 1

Well, I was thinking maybe the message id is, by default, set as list item instead of string and that might be the reason why it can't find it in the list though the list contains the id. So I just edited it and it works!
I forgot to mention that the script was taken from <a href=http://homepage.mac.com/barryw/">Barry Wainwright's "Remove Duplicates" for Entourage.
Here's the edited blocks:
<pre>repeat with this_msg in all_msg
try
set msg_id to (content of every header ¬
of this_msg whose name is "Message-ID") ¬
as string -- problem was here
if msg_id is "" then set background color ¬
of this_msg to blue
end try
if msg_id is in id_list then
set background color of this_msg to gray
set flagged status of this_msg to ¬
true -- for easy deletion
set dup_count to dup_count + 1
else if msg_id is not "" then
set the end of id_list to msg_id
end if
set msg_count to msg_count - 1
if msg_count mod 100 = 0 and msg_count > 0 ¬
then say (msg_count as string) ¬
& " messages remaining"
end repeat
if dup_count is 0 then
say "done. no duplicates found"
else if dup_count is 1 then
say "done. 1 duplicate found"
-- sometimes you only find one
else
say "done. " & dup_count & " duplicates found."
end if
</pre>