Applescript move files

Question

I have this applescript that when i place files in a folder on my desktop it will prompt me for a subject and email it to my gmail account. I wanted to add a line that would kick those file(s) back out to my desktop apon completion. It sends the files but will not proceed... if i run it in the script editor it does kick them out... why arent both of my commands running?
[ code ]
on adding folder items to thefolder after receiving theAddedItems
repeat with eachitem in theAddedItems
set theSender to "Me<[email protected]>"
set recipCommon to "Files"
set recipAddress to "[email protected]"
set msgText to "Some text"
tell application "Mail"
set newmessage to make new outgoing message with properties {content:msgText & return}
tell newmessage
set sender to theSender
display dialog "Please Enter a Subject:" default answer ""
set theSubject to text returned of result
set subject to theSubject
make new to recipient with properties {name:recipCommon, address:recipAddress}
make new attachment with properties {file name:eachitem} at after the last paragraph
end tell
send newmessage
end tell
end repeat
end adding folder items to
try
tell application "Finder"
move every file of folder "Macintosh HD:Users:home:Desktop:somefolder:" to folder "Macintosh HD:Users:home:Desktop:"
end tell
end try

Answer 1

You can't run a folder action script in an open Script Editor window without substituting variables.
A better solution would be to not even use a folder action to begin with, since you want the file to remain on your desktop anyway. This variation makes you select one or several files from a dialog while leaving the files intact:
set theItems to choose file with multiple selections allowed
repeat with eachItem in theItems
set theSender to "Me<[email protected]>"
set recipCommon to "Files"
set recipAddress to "[email protected]"
set msgText to "Some text"
tell application "Mail"
set newmessage to make new outgoing message with properties {content:msgText & return}
tell newmessage
set sender to theSender
tell application "Finder" to display dialog "Please Enter a Subject:" default answer (name of eachItem as string)
set theSubject to text returned of result
set subject to theSubject
make new to recipient with properties {name:recipCommon, address:recipAddress}
make new attachment with properties {file name:eachItem} at after the last paragraph
end tell
send newmessage
end tell
end repeat
Another possibility might be to make a "droplet", where you drop the file(s) on the script to send them.
But the most elegant Mac-like solution is to use the Applescript menu.
Enable the Applescript menu and you will have a fast convenient way to access any script for any application. There are some super cool tricks with Script Menu.
To enable the Applescript Menu, open the application at
/Applications/AppleScript/AppleScript\ Utility.app
and select "Show Script Menu". The frontmost application (in focus) has its own script menu so it is always changing. You can create a folder for the frontmost application by clicking the menu icon, then selecting "Open Scripts Folder", then "Open ** Scripts Folder". A new empty window will appear ready for you to populate with Applescripts. That is too cool!
Put your script in that folder and now whenever Mail.app is in front you have fast access to the script.
But alas, selecting files from a dialog is not convenient enough for us Mac folk, so here is the easiest way of all.
Replace the first line of the script with this one:
tell application "Finder" to set theItems to the selection
Now all you have to do is select (highlight) the files in any window and bring Mail.app to the front and click the Applescript icon. That is too easy!