Applescript to open various files and add info from filename to the file

Question

Hi guys,
first time using this forum...
and first time trying to do a script for apple...
I figured out how to do simple things... like open files and stuff to text files...  but don't know where to begin:
I have a directory datalogs...
within the directory i have multiple text files that have the following format:
dataXXYYY_Waf2_7_19_11.csv
dataXXYYY_Waf3_7_19_13.csv
dataXXYYY_Waf25_7_19_16.csv
typically 25 files, but sometimes less
I would like to be able to take each file within the datalogs folder ...
Scan the file name and look for the number afer Waf
The number can be anywhere from (single digit) 1 to 25
I would like to take that value after Waf  and then append a line in the txt file
the line I would have to add will be 5 rows down and it shoulld say:
wafer,1 
the 1 above is the value that was in the file name....
i.e.
for the file
dataXXYYY_Waf25_7_19_16.csv
before append the file contains random data ... i.e.
dummyline1
dummyline2
dummyline3
dummyline4
dummyline5
dummyline6
Then after the script...
the file will be saved with same name:
dataXXYYY_Waf25_7_19_16.csv
and the data should look like:
dummyline1
dummyline2
dummyline3
dummyline4
wafer,25
dummyline5
dummyline6
any help will be appreciated
-thanks

Answer 1

Copy your source folder - named 'datalogs' to your home directory and run this script by copying into a new AppleScript Editor document and pressing Run. 
I think I've followed your specification, and there will be other ways to do this, but ask if you have questions.  (I have put comments in the code which should explain some of it!)
There is no error checking, but I have made copies of the original files in the source directory.  (You can comment out the line "duplicate theFile" by prefixing with "--" when you are sure it's working.
As always, ensure your data is backed-up before proceeding.
--starts here
--sets path to datalogs folder
set theDirectory to (path to home folder as text) & "datalogs"
set fileNames to {}
tell application "Finder"
  --gets all the files in the source directory
          set fileList to files of folder theDirectory
  --iterates through the files
          repeat with theFile in fileList
  --makes a duplicate
  duplicate theFile
  --puts the fileName and fileLocation into records in a list of lists
                    set end of fileNames to {fileName:name of theFile, fileLoc:theFile as alias}
          end repeat
  --iterates thru the files
          repeat with theFile in fileNames
  --gets offset of the string "Waf"
                    set WafOffset to offset of "Waf" in (fileName of theFile)
  --trims the name so that it now starts with the character after "Waf"
                    set fileName to text (WafOffset + 3) thru end of fileName of theFile
  --gets offset of the next underscore
                    set UScoreOffset to offset of "_" in fileName
  --stores the desired number by trimming off the end of the file name
                    set fileNumber to text 1 thru (UScoreOffset - 1) of fileName
  --sets up the text to insert by prefixing with "Wafer," and suffixing with return
                    set insertText to "Wafer," & fileNumber & character id 10
  --opens the file with write permission
                    set FileRef to open for access (fileLoc of theFile) with write permission
  --initialise container
                    set fileContents to ""
  --puts first five lines into container
                    repeat 5 times
                              set fileContents to fileContents & (read FileRef until character id 10)
                    end repeat
  --adds the new text to the container
                    set fileContents to fileContents & insertText
  --adds the rest of the file to the container
                    set fileContents to fileContents & (read FileRef)
  --effectively empties the file
  set eof FileRef to 0
  --writes contents of the container to the file
  write fileContents to FileRef
  --closes the file
  close access FileRef
          end repeat
end tell
--ends here