Applescript to switch audio output

Question

I am having a little trouble with this applescript which is intended to present a dialog with some choices and switch the audio output accordingly. Any help would be greatly appreciated. I've started a gist too.
tell application "System Preferences" to activate
tell application "System Events"
          get properties
          set asrc to choose from list {"Internal Speakers", "Living Room", "Girl's Room", "Master Bedroom"} with title "Sound Picker" default items {"Internal Speakers"}
          display dialog "src is: " & asrc
          tell process "System Preferences"
                    click menu item "Sound" of menu "View" of menu bar 1
  delay 2
                    set theRows to every row of table 1 of scroll area 1 of ¬
                              tab group 1 of window "sound"
                    set theOutputs to {} as list
                    repeat with aRow in theRows
                              if (value of text field 1 of aRow as text) ¬
                                        is equal to asrc then
                                        set selected of aRow to true
                                        exit repeat
                              end if
                    end repeat
          end tell
end tell
tell application "System Preferences" to quit

Answer 1

Hi,
The following script, tested under OS X 10.8.2, should do the trick.
set asrc to (choose from list {"Internal Speakers", "Living Room", "Girl's Room", "Master Bedroom"} with title "Sound Picker" default items {"Internal Speakers"}) as text
if result is "false" then return
display dialog "src is: " & asrc
tell application "System Preferences"
    reveal anchor "output" of pane id "com.apple.preference.sound"
    activate
    tell application "System Events"
        tell process "System Preferences"
            select (row 1 of table 1 of scroll area 1 of tab group 1 of window "Sound" whose value of text field 1 is asrc)
        end tell
    end tell
    quit
end tell
To have the script run in the background, just comment out the “activate” line above.
You might also have a look at this web page.
Message was edited by: Pierre L. (fixed the web link)