Applescript vs PDF more pages vs Tiff

Question

Does anyone know a script that can makes tiff images from a multipage PDF.
I don't know how to automate this procces in photoshop, Because the PDF files have more or less pages and I need a tiff image from every page.
Does anyone know this. So a folder with PDF files and make tiff images from every page of every PDF. Keeping the file name and add the page number at the end?
PDF : 2008-merging.pdf / 2008-merging.pdf-p1.tiff / 2008-merging.pdf-p2.tiff / ...
If you know this , it would be great if you want to share it.
Thank in advance.

Answer 1

Here is a old script that should get you going. I did this some time back when on Panther there are better methods for finding the number of pages in PDF in Tiger I just have not had the time to bring this up to date.
set TodaysDate to do shell script "date \"+%d-%m-%y\""
-- Create new folder to save to
tell application "Finder"
set RasterImages to make new folder at desktop with properties ¬
{name:"Rasterized PDF's " & TodaysDate}
end tell
-- Check for application processes else launch
tell application "System Events"
if not (exists process "Acrobat") then
launch application "Adobe Acrobat 7.0 Professional"
end if
if not (exists process "Adobe Photoshop CS2") then
launch application "Adobe Photoshop CS2"
end if
end tell
-- Set Photoshop settings
tell application "Adobe Photoshop CS2"
set display dialogs to never
set UserPrefs to properties of settings
set ruler units of settings to pixel units
-- set background color to {class:CMYK color, cyan:0, magenta:0, yellow:0, black:0}
-- set foreground color to {class:CMYK color, cyan:0, magenta:0, yellow:0, black:100}
end tell
-- Get list of PDF's
set Q1 to "Do you want to include all the subfolders" & return & "within your folder selection?"
set theDialog to display dialog Q1 buttons {"No", "Yes"} default button 1 with icon note
if button returned of theDialog is "Yes" then
set inputFolder to choose folder with prompt "Where is the top level folder of PFD's?" without invisibles
tell application "Finder"
set filesList to (files of entire contents of inputFolder whose name extension is "pdf")
end tell
else
tell application "Finder"
set inputFolder to choose folder with prompt "Where is the folder of PFD's?" without invisibles
set filesList to (files of inputFolder whose name extension is "pdf")
end tell
end if
set countA to count of filesList
if countA = 0 then
display dialog "This folder contains no PDF files to rasterize!" giving up after 2
end if
-- Loop through the files in list
repeat with aFile in filesList
tell application "Finder"
set theFile to aFile as alias
end tell
-- Open in Acrobat to count the pages
tell application "Adobe Acrobat 7.0 Professional"
-- activate
open theFile with invisible
tell document 1
set PageCount to count of pages
end tell
close document 1 saving no
end tell
-- Loop Photoshop through the page count
repeat with i from 1 to PageCount
tell application "Adobe Photoshop CS2"
activate
open theFile as PDF with options ¬
{class:PDF open options, bits per channel:eight, constrain proportions:true, crop page:trim box, mode:CMYK, page:i, resolution:300, suppress warnings:true, use antialias:true, use page number:true}
set docRef to the current document
tell docRef
flatten
-- New file naming options
set docName to name of docRef
set ASTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to " "
set docName to text items of docName
set AppleScript's text item delimiters to "_"
set docName to docName as string
set AppleScript's text item delimiters to "-"
set docName to text item 1 of docName
set AppleScript's text item delimiters to ASTID
if PageCount = 1 then
set newFileName to (RasterImages as string) & docName & ".tif"
else
set fileNum to ""
repeat until (length of (fileNum as text)) = (length of (PageCount as text))
if fileNum = "" then
set fileNum to i
else
set fileNum to "0" & fileNum
end if
end repeat
set newFileName to (RasterImages as string) & docName & "_" & fileNum & ".tif"
end if
end tell
save docRef in file newFileName as TIFF with options {byte order:Mac OS, embed color profile:true, image compression:LZW, save alpha channels:false, save layers:false}
close current document without saving
end tell
end repeat
end repeat
-- Set ruler units back to user prefs
tell application "Adobe Photoshop CS2"
set ruler units of settings to ruler units of UserPrefs
end tell