Automatically create and sort into subfolders

Question

Hi,
I have a large folder directory with a lot of photos in them.
Basically something like
Clouds
Cloud_01
Cloud_02
etc.
Trees
Tree_01
Tree_02
Each subfolder has both .jpg and .cr2 (raw) files in them
I'd like to be able to run a script or automator sequence which will automaticall look inside these folders, and then create folders RAW and JPG and then put the corresponding files into the correct folder based on the filetype. So I'll wind up with something like this:
Clouds
Cloud_01
JPGAll JPG files
RAWAll RAW files
Cloud_02
JPG
RAW
etc.

Answer 1

Maybe something like this:
set theMainFolder to choose folder
tell application "Finder"
    set theFolders to folders of theMainFolder
    repeat with thisFolder in theFolders
        set theSubFolders to folders of thisFolder
        repeat with thisSubFolder in theSubFolders
            if not (exists (folder "JPG" of thisSubFolder)) then
                make new folder at thisSubFolder with properties {name:"JPG"}
            end if
            if not (exists (folder "RAW" of thisSubFolder)) then
                make new folder at thisSubFolder with properties {name:"RAW"}
            end if
            move (files of thisSubFolder whose name extension is "jpg") ¬
                to folder "JPG" of thisSubFolder with replacing
            move (files of thisSubFolder whose name extension is "cr2") ¬
                to folder "RAW" of thisSubFolder with replacing
        end repeat
    end repeat
end tell