Automatically run workflows

Question

ok, i'm new to automator but not to mac. I just made myself a workflow from a guide to sync to itunes libraries. it gets the specified servers but when it tries to connect, the spiral thing just keeps spinning.
How do i get this to work?
Regards

Answer 1

I just added some options (oops, it looks like a character got lost in there, too). I have an AppleScript that uses rsync with logging, and it produces itemized changes in the logs. Running it with the --dry-run option (which doesn't actually do any copying), the command is something like:
/usr/bin/rsync --archive --extended-attributes --human-readable --delete --dry-run --itemize-changes --verbose --log-file='/Users/johndoe/library/Logs/rsync.log' '/Users/johndoe/Music/iTunes/' '/Volumes/johndoe/Music/iTunes'
On second thought, here is the complete script - give it a try (especially with the dry run option) and see if you get different results:
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFD760;
overflow: auto;"
title="this text can be pasted into the Script Editor">
-- use rsync to sync a source folder to a destination - only new or modified files are copied
-- see http://developer.apple.com/documentation/Darwin/Reference/ManPages/man1/rsync.1. html
property SourceFolder : missing value -- the Finder path to the folder containing the files to copy
property DestinationFolder : missing value -- the Finder path to the folder to copy to
property DeleteFiles : true -- delete destination files if they no longer exist in the source?
property ExtendedAttributes : true -- include extended attributes?
property DryRun : false -- testing?  if so, don't actually do anything, just show what would have happened
try
SourceFolder as alias -- test
on error
set SourceFolder to (choose folder with prompt "Select a source folder:")
end try
set SourceFolder to quoted form of POSIX path of SourceFolder -- format for the shell script
try
DestinationFolder as alias -- test
on error
set DestinationFolder to (choose folder with prompt "Select a destination folder:")
end try
set DestinationFolder to quoted form of POSIX path of DestinationFolder -- format for the shell script
set LogFile to (POSIX path of ((path to home folder) as text) & "library/Logs/AS_rsync.log") -- a console log
set Command to "/usr/bin/rsync --archive --human-readable "
if ExtendedAttributes then set Command to Command & "--extended-attributes "
if DeleteFiles then set Command to Command & "--delete "
set Command to Command & ¬
"--exclude='.DS_Store' " & ¬
"--exclude='.Trash*' " & ¬
"--exclude='cache*' " & ¬
"--exclude='Cache*' " & ¬
"--exclude='SyncServices' " -- files to exclude
if DryRun then set Command to Command & "--dry-run --itemize-changes --verbose "
log Command & "--log-file=" & (quoted form of LogFile) & space & SourceFolder & space & DestinationFolder
do shell script Command & "--log-file=" & (quoted form of LogFile) & space & SourceFolder & space & DestinationFolder
if DryRun then
(choose from list (paragraphs of the result) with prompt "dry run results:" with empty selection allowed)
else
tell application "Console" to open LogFile as POSIX file
end if
</pre>