Campaign execution not send emails for contact persons

Question

Hi All!
I'm facing a problem with Campaigns (communication medium - E-mail): Those are the steps i'm following:
1.Start the campaign, and on the "campaign: Schedule job" screen, i choose  "immediately". If i look at the campaign details after scheduled the job, the status is now "job started".
2. To check wich mails were sent, I also had a look at the business partner account that belongs to the target group used. On the "Interaction History" block, there is a line: "Outgoing Email" - on the details of this outgoing email I can see the "To" (Receivers). And here, I have emails from the business Partner contact persons and from the business partner itself (the email that is on the header level of the business partner account, on the "main address and communication data" area). So far so good. That's exactly what i need but,
3. If i go to the tcode, i only have a send request for the business partner itself and none for his contact persons (although those emails are on the "To" line for the interaction history).
I'm working on the Webclient UI, of the CRM 7.0
Does someone knows why the emails are not being sent also for the contact persons?
Thanks in advance.
Inê

Answer 1

I have achieved this by implementing the BADI : CRM_MKT_ADR_SEARCH
In this BADI's method : CHANGE_SEARCH_RESULTS you can modify the data which is being sent back to system for campaign execution.
NOTE: I am using Address Independent Communication Data of Business Partner
Below is my sample code for contact person email :
  data: wa_bp_cp_channel type crmt_bp_cp_channel.
  field-symbols: <fs_bp_cp_channel> type crmt_bp_cp_channel.
  types: begin of ty_cp,
          partner type but000-partner,
          address type but000-addrcomm,
         end of ty_cp,
         begin of ty_bpcp,
           partner1 type but051-partner1,
           partner2 type but051-partner2,
         end of ty_bpcp.
  data: it_cp type table of ty_cp,
        wa_cp type ty_cp.
  data: it_bpcp type table of ty_bpcp,
        wa_bpcp type ty_bpcp.
  data: it_bp type table of ty_cp,
        wa_bp type ty_cp.
  read table ct_bp_cp_channel into wa_bp_cp_channel with key com_channel = '03'.
  if sy-subrc = 0.
    select partner addrcomm
      from but000
        into table it_cp
          for all entries in ct_bp_cp_channel
            where
              partner = ct_bp_cp_channel-cp_number.
    select partner1 partner2
      from but051
        into table it_bpcp
          for all entries in ct_bp_cp_channel
            where
              partner1 = ct_bp_cp_channel-bp_number.
    if it_bpcp[] is not initial.
      select partner addrcomm
        from but000
          into table it_bp
            for all entries in it_bpcp
              where
                partner = it_bpcp-partner2.
    endif.
    sort it_cp by partner.
    sort it_bp by partner.
    sort it_bpcp by partner1.
    loop at ct_bp_cp_channel assigning <fs_bp_cp_channel> where com_channel = '03'.
      read table it_cp into wa_cp with key partner = <fs_bp_cp_channel>-cp_number binary search.
      if sy-subrc = 0.
        <fs_bp_cp_channel>-addrnumber = wa_cp-address.
        clear <fs_bp_cp_channel>-bp_number.
        clear <fs_bp_cp_channel>-bp_guid.
      else.
        read table it_bpcp into wa_bpcp with key partner1 = <fs_bp_cp_channel>-bp_number binary search.
        if sy-subrc = 0.
          read table it_bp into wa_bp with key partner = wa_bpcp-partner2 binary search.
          if sy-subrc = 0.
            <fs_bp_cp_channel>-addrnumber = wa_bp-address.
            clear <fs_bp_cp_channel>-bp_number.
            clear <fs_bp_cp_channel>-bp_guid.
          endif.
        endif.
      endif.
    endloop.
  endif.