Can anyone spot the error in this script for iTunes?

Question

This AppleScript is designed to copy the Name and Artist of an iTunes track, then populate the Album Artist field with both, separated with an oblique. But when I run the script in iTunes, it only pastes the Artist name in to the Album Artist field and not the whole string.
tell application "iTunes"
if selection is not {} then -- if tracks are selected...
set sel to selection
set numTracks to (length of sel)
set s to "s"
if numTracks is 1 then set s to ""
display dialog "Adds the name of the track and the name of the artist to the Album Artist field." & return & return & (numTracks & " track" & s & " selected.") buttons {"Cancel", "Continue"} default button 2 with title "Create Album Artist" giving up after 30
if gave up of result is true then return
repeat with t from 1 to numTracks
tell contents of item t of sel
set {album artist} to ({get artist} & " / " & {get name})
end tell
end repeat
else
display dialog "No tracks have been selected." buttons {"Cancel"} default button 1 with icon 0 giving up after 30
end if -- no selection
end tell

Answer 1

Hello
Try -
tell item t of sel
set album artist to (get artist) & " / " & (get name)
end tell
instead of -
tell contents of item t of sel
set {album artist} to ({get artist} & " / " & {get name})
end tell
In your original code, the left and right value of assignment are both list, i.e. -
left value = {album artist}
right value = {get artist, "/", get name}
Consequently 'album artist' is assigned to the 1st item of the list at right, which is the result of 'get artist'.
In order to avoid this, don't use list assingment, which is not necessary at all here.
Also, I think you may just tell item t of sel, not contents of item t of sel.
Hope this may help,
H