Can this simple script be made quicker? Color labels

Question

All this does is turn all the selected items red, it works but it is not as qucik as selecting all the files right click and select color label.
In the manual method you see all the files turn red at the same time, whereas below you see it happen 1 by one.
tell application "Finder"
  activate
          set selected to selection
          repeat with n_file in every item in selected
                    set label index of n_file to 2
          end repeat
end tell

Answer 1

Hi,
If you want a faster script, you can use this script (python shell) :
-- none = 0, gray = 2, green = 4, purple = 6, blue = 8, yellow = 10, red = 12, orange = 14
set tColor to 12 -- red
tell application "Finder" to set sel to selection as alias list
repeat with i in sel
      tell i to set contents to quoted form of POSIX path of it
end repeat
set oTID to text item delimiters
set text item delimiters to " "
set sel to sel as string -- arguments for the shell
set text item delimiters to oTID
do shell script "/usr/bin/env python -c 'from sys import argv; from xattr import xattr
color = chr(int(argv[1]))
nbr = len(argv)
for i in range( 2, nbr ):
   try:
        attrs = xattr(argv[i])
        try:
            finder_attrs = attrs[u\"com.apple.FinderInfo\"]
        except:
            finder_attrs = 32*chr(0)
        finder_attrs = finder_attrs[:9] +  color + finder_attrs[10:]
        attrs.set(u\"com.apple.FinderInfo\", finder_attrs)
   except:
           print argv[i]'  " & tColor & " " & sel
The shell return  the files path that have not been processed (error : permissions, locked, ...).
Here is the bench on my old machine (156 selected files) :
-     9.4 seconds,  script using  the Finder
-      3.4 seconds,  script using  the Finder and (selection as alias list)
-      0.24 second, my script.