Cant open ical to backup calendar

Question

I had to reformat my computer due to an OS error. Luckily I backed up my whole HD on an extrernal drive before I reformatted. I need to know where the files that store all my ical info are located so I can somehow put them back into my new fresh calendar.
I didn't backup my calendars from ical, I just copyed my whole HD and need to know where the calendar files are normally stored.
thanks

Answer 1

Hi Justin,
In Tiger the calendar files are stored in folders in Library> Application Support> iCal. The name of the calendar is stored in the info.plist file and the actual data is stored in the corestorage.ics file.
I have an Applescript that makes a valid iCal backup file on your desktop from this. Copy and paste the blue text below into Script Editor (Applications>Applescript>Script Editor), press run and navigate to your old Application Support folder. You should then be able to choose File>Revert To Database Backup... from iCal and select the file on your Desktop.
-- Make iCal Backup --
-- Makes icbu file for iCal at user's Desktop.
-- Will only work in 10.4.
-- John Maisey -- 5th September 2005 -- 1.1
-- Added option to locate info in other locations. 15 Jan 2006
set myPath to (path to desktop from user domain)
set myAppSuppPath to alias ((choose folder with prompt "Locate your old Applcation Support folder.") & "iCal" as text)
set myNowFormat to do shell script "date +%FT%TZ"
set myDayFormat to do shell script "date +%d/%m/%Y"
set myNewName to ("iCal " & myDayFormat & ".icbu") as text
set myPreamble to "<?xml version=\"1.0\" encoding=\"UTF-8\"?>" & return & "<!DOCTYPE plist PUBLIC \"-//Apple Computer//DTD PLIST 1.0//EN\" \"http://www.apple.com/DTDs/PropertyList-1.0.dtd\">" & return & "<plist version=\"1.0\">" & return & "<dict>" & return & " <key>date</key>" & return & " <date>"
set myPostamble to "</date>" & return & " <key>version</key>" & return & " <string>1.0</string>" & return & "</dict>" & return & "</plist>"
set myPlist to (myPreamble & myNowFormat & myPostamble)
tell application "Finder"
if exists file myNewName of myPath then
set myButton to button returned of (display alert "\"" & myNewName & "\" already exists" message "Would you like to replace this file?" as warning buttons {"Cancel", "Replace"} default button 2 giving up after 120)
if myButton is "Replace" then
delete file myNewName of myPath
else
return
end if
end if
set myFolder to (duplicate myAppSuppPath to myPath)
delete (files of myFolder whose name contains "sync" or name contains "alarms")
set myInfoPlist to make new file at myFolder with properties {name:"Info.plist"}
my WriteToFile(myInfoPlist as text, myPlist, true)
set name of myFolder to myNewName
end tell
--handler to write text to text file with flag to clear text before
on WriteToFile(theFile, theText, clearFLag)
try
open for access file theFile with write permission
end try
if clearFLag is true then
set eof of file theFile to 0
end if
write theText & return to file theFile starting at eof
try
close access file theFile
end try
end WriteToFile
Post back if you have any problems with this.
Best wishes
John M