Catching message errors after submit

Question

Is there any way to catch message after submitting report?
I mean any type of message, i.e. E,S,I and so on. And if it's possible, I need to suppress them. Maybe this can work with help of the system calls?

Answer 1

HI Vitaly,
You can try the 'SUBMIT VIA JOB' option and then read the job log and/or spool for any messages. Here is a rough code.
  DATA: l_jobcount LIKE tbtcjob-jobcount.
  CALL FUNCTION 'JOB_OPEN'
       EXPORTING
            jobname          = 'MYTESTJOB'
       IMPORTING
            jobcount         = l_jobcount
       EXCEPTIONS
            cant_create_job  = 1
            invalid_job_data = 2
            jobname_missing  = 3
            OTHERS           = 4.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE 'I' NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4
            INTO i_return_messages-message.
    i_return_messages-type = 'E'.
    APPEND i_return_messages.
    CLEAR i_return_messages.
    EXIT.
  ENDIF.
  SUBMIT zbwm_sap_to_dsc_enr_rel_notice
    WITH p_relno = release_nbr
    USER sy-uname VIA JOB 'MYTESTJOB'
  NUMBER l_jobcount AND RETURN.
  CALL FUNCTION 'JOB_CLOSE'
       EXPORTING
            jobcount             = l_jobcount
            jobname              = 'MYTESTJOB'
            strtimmed            = 'X'
       EXCEPTIONS
            cant_start_immediate = 1
            invalid_startdate    = 2
            jobname_missing      = 3
            job_close_failed     = 4
            job_nosteps          = 5
            job_notex            = 6
            lock_failed          = 7
            OTHERS               = 8.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE 'I' NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4
            INTO i_return_messages-message.
    i_return_messages-type = 'E'.
    APPEND i_return_messages.
    CLEAR i_return_messages.
  ENDIF.
After this, you will have to check if the job has completed or not(in a loop). To do that you can call the function module SHOW_JOBSTATE. This will tell the status of the job. Once the job status is 'FINISHED' or 'ABORTED', you can then call another function module BP_JOBLOG_READ to read the job log.
But again, you will have parse through the text to identify the message type, number, message text etc.