CL_ABAP_TYPEDESCR does not return integer or decimal field

Question

Dear All,
I have an internal table for which I want to get dynamically list of fields.
I use class CL_ABAP_TYPEDESCR and method DESCRIBE_BY_DATA.
The list of field is then placed in table CL_ABAP_TYPEDESCR->KEY. The problem
is that fields with integer type (FIELD FACTOR) are not listed there. What do I do wrong?
TYPES: BEGIN OF t_table,
        name(20)   TYPE C,
        period(10) TYPE C,
        factor     TYPE I,
      END OF t_table.
DATA: it_table TYPE STANDARD TABLE OF t_table.
DATA: wa_table TYPE t_table.
wa_table-name = 'Brown'. wa_table-period = '2010'. wa_table-factor = 100. APPEND wa_table TO it_table.
wa_table-name = 'Brown'. wa_table-period = '2011'. wa_table-factor = 200. APPEND wa_table TO it_table.
wa_table-name = 'Fox'.   wa_table-period = '2010'. wa_table-factor = 50.  APPEND wa_table TO it_table.
wa_table-name = 'Fox'.   wa_table-period = '2010'. wa_table-factor = 900. APPEND wa_table TO it_table.
TYPE-POOLS: ABAP.
DATA: L_REF TYPE REF TO CL_ABAP_TABLEDESCR.
l_ref ?= CL_ABAP_TYPEDESCR=>DESCRIBE_BY_DATA( it_table ).
* TABLE l_ref->key DOES NOT SHOW FIELD "FACTOR" (TYPE I)....
FIELD-SYMBOLS: <KEY_COMP_WA> TYPE ABAP_KEYDESCR.
LOOP AT l_ref->key ASSIGNING <KEY_COMP_WA>.
   WRITE:/ <KEY_COMP_WA>-NAME.
ENDLOOP.
Best regards,
Mark

Answer 1

Hi Mark,
if you want the fields you should consider attribute components, compare this snippet getting the field names of any structure or table (from the times when I still used FORM routines)
FORM getfields
  USING    px_data                        TYPE any
  CHANGING pt_fields                      TYPE table.
  DATA:
    lt_comp                               TYPE abap_compdescr_tab,
    lr_dat                                TYPE REF TO data,
**    lv_kind                             TYPE abap_typecategory,
    lr_typedescr                          TYPE REF TO cl_abap_typedescr,
**    lr_tabledescr                       TYPE REF TO cl_abap_tabledescr,
    lr_structdescr                        TYPE REF TO cl_abap_structdescr.
  FIELD-SYMBOLS:
    <fs>                                  TYPE ANY,
    <ft>                                  TYPE ANY TABLE,
    <comp>                                TYPE LINE OF abap_compdescr_tab.
  lr_typedescr ?= cl_abap_typedescr=>describe_by_data( px_data ).
  CASE lr_typedescr->kind.
    WHEN 'S'.
      lr_structdescr ?= lr_typedescr.
      lt_comp                             = lr_structdescr->components.
    WHEN 'T'.
      ASSIGN px_data TO <ft>.
      CREATE DATA lr_dat                  LIKE LINE OF <ft>.
      ASSIGN lr_dat->* TO <fs>.
      lr_structdescr ?= cl_abap_structdescr=>describe_by_data( <fs> ).
      lt_comp                             = lr_structdescr->components.
    WHEN OTHERS.
      MESSAGE e241(00).
*   Function is invalid in this environment
  ENDCASE.
  CLEAR pt_fields.
  LOOP AT lt_comp ASSIGNING <comp>.
    APPEND <comp>-name TO pt_fields.
  ENDLOOP." at lt_comp assigning <comp>.
ENDFORM.                    " getfields
Regards,
Clemens