Class for Purchase order item components and Production order components

Question

I'm looking for a some classes.   I'm very new to objects, so I could be searching for them incorrectly.
The first class I'm looking for is a purchase order class that contains the item components.  I've looked at CL_PO_ITEM_HANDLE_MM and CL_PO_HEADER_HANDLE_MM.  I couldn't find components as a part of either of the classes.
The second one I'm looking for is not as critical.  It is for the components for a production order.   I have a function module: BAPI_PRODORD_GET_DETAIL that gets the components for the order.  However, to take advantage of objects - I read somewhere - that if possible I should avoid calling a function module.
Any help that you could give would be greatly appreciated.
Thank you!
Michelle

Answer 1

Hello Michelle
I do not think there are already classes available on ERP 6.0 for reading production order (yet I might be wrong...). However, regarding purchase order you are already on the right track.
*& Report  ZUS_SDN_OO_READ_PO
*& Thread: Class for Purchase order item components and Production order components
*& <a class="jive_macro jive_macro_thread" href="" __jive_macro_name="thread" modifiedtitle="true" __default_attr="1206523"></a>
"& NOTE: Coding adapted from BAPI_PO_GETDETAIL1
REPORT  zus_sdn_oo_read_po.
TYPE-POOLS: abap, mmpur.
PARAMETER:
  p_ebeln   TYPE ebeln  DEFAULT '3000000045'.
DATA: gs_document    TYPE mepo_document,
      go_po          TYPE REF TO cl_po_header_handle_mm,
      gs_header      TYPE mepoheader,
      gd_tcode       TYPE sy-tcode,
      gd_result      TYPE mmpur_bool.
data: gt_items       type PURCHASE_ORDER_ITEMS,
      gs_itm         type PURCHASE_ORDER_ITEM,
      gs_item        type mepoitem.
START-OF-SELECTION.
*  prepare creation of PO instance
  gs_document-doc_type    = 'F'.
  gs_document-process     = mmpur_po_process.
  gs_document-trtyp       = 'A'.  " anz.  => display
  gs_document-doc_key(10) = p_ebeln.
*  object creation and initialization
**  l_ebeln = purchaseorder.
  CREATE OBJECT go_po.
  CALL METHOD go_po->po_initialize( im_document = gs_document ).
  CALL METHOD go_po->set_po_number( im_po_number = p_ebeln ).
  CALL METHOD go_po->set_state( cl_po_header_handle_mm=>c_available ).
*  read purchase order from database
  gd_tcode = 'ME23N'.
  CALL METHOD go_po->po_read
    EXPORTING
      im_tcode     = gd_tcode
      im_trtyp     = gs_document-trtyp
      im_aktyp     = gs_document-trtyp
      im_po_number = p_ebeln
      im_document  = gs_document
    IMPORTING
      ex_result    = gd_result.
*  there was a problem in reading the PO
  IF ( gd_result EQ mmpur_no ).
**    l_messages = l_handler->get_list_for_bapi( ).
**    PERFORM return TABLES l_messages return
**                          poitem poschedule poaccount.
**    CALL METHOD l_po->po_close( ).
  ELSE.
    gs_header = go_po->if_purchase_order_mm~get_data( ).
    WRITE: / gs_header-ebeln,
             gs_header-bukrs,
             gs_header-bsart,
             gs_header-lifnr.
  ENDIF.
  gt_items = go_po->if_purchase_order_mm~get_items( ).
  LOOP AT gt_items INTO gs_itm.
    gs_item = gs_itm-item->get_data( ).
    write: / gs_item-ebelp,
             gs_item-matnr,
             gs_item-menge.
  ENDLOOP.
END-OF-SELECTION.
Regards
  Uwe