Computer Name to be retrieved

Question

Hi All,
How to retrieve the computer name of the user who is working on a SAP System.
Pointers would be helpful.
Thanks,
Best regards,
Prashant

Answer 1

hi prashant ,
just execute this code and see if it suffice ur need .
regards,
TVK.
DATA SI LIKE RFCSI.
CALL FUNCTION 'RFC_SYSTEM_INFO' DESTINATION 'SAPGUI'
    IMPORTING
        RFCSI_EXPORT = SI.
WRITE:
/ 'RFC log version:', SI-RFCPROTO,
/ 'Character set (SAP name):', SI-RFCCHARTYP,
/ 'Integer format (1 / 2 = little / big endian):', SI-RFCINTTYP,
/ 'Floating point format (1=IEEE, 2=IBM/370 format):', SI-RFCFLOTYP,
/ 'Logical destination (specified when calling function):', SI-RFCDEST,
/ 'Host:', SI-RFCHOST,
/ 'System: SAP System ID:', SI-RFCSYSID,
/ 'System: SAP System ID:', SI-RFCDATABS,
/ 'Database host name:', SI-RFCDBHOST,
/ 'System: Database system:', SI-RFCDBSYS,
/ 'System: SAP Release:', SI-RFCSAPRL,
/ 'RFC: SAP machine ID:', SI-RFCMACH,
/ 'System: Operating system:', SI-RFCOPSYS,
/ 'Time zone (difference from UTC in seconds):', SI-RFCTZONE,
/ 'Summertime active ? (''daylight saving time''):', SI-RFCDAYST,
/ 'IP address:', SI-RFCIPADDR.
skip 3.
DATA: W_HOSTADDR LIKE  MSXXLIST-HOSTADR,
        W_TERMINAL(30) TYPE C,
        w_1 type i,
        w_2 like w_1,
        w_3 like w_1,
        w_4 like w_1.
  CALL FUNCTION 'TH_USER_INFO'
       IMPORTING
            HOSTADDR            = W_HOSTADDR
            TERMINAL            = W_TERMINAL
       EXCEPTIONS
            OTHERS              = 1.
  IF SY-SUBRC = 0.
    w_1 = W_HOSTADDR(1).
    w_2 = W_HOSTADDR+1(1).
    w_3 = W_HOSTADDR+2(1).
    w_4 = W_HOSTADDR+3(1).
    WRITE: / 'IP address:', w_1,'.',w_2,'.',w_3,'.',w_4,
           / 'Terminal  :', W_TERMINAL.
  ELSE.
    WRITE / 'Unknown Error.'.
  ENDIF.