Count of columns in a query

Question

All,
Could anyone please clarify me on , how we can count the column's which were used in a query.
Ex:    SELECT ENAME, EMPNO, SAL , JOB FROM EMP; 
--Here in the above query, I have taken 4 columns(counted manually) . Instead of counting it manually is there any other way.
Thanks

Answer 1

It sounds like you're creating dynamic SQL.  Why are you doing that?  Dynamic SQL's would seem to indicate you don't know the structure of your own database or that your application design is trying to be generic rather than being designed in proper modularized units (1 unit does 1 task, not multiple generic tasks).  99.999% of the time, people using dynamic SQL indicates that they are misusing the database or haven't designed things properly.
If there's really a valid reason for using dynamic SQL, then of course you can do it properly and use all the features of Oracle to get information about the dynamic SQL, but that means not using something as poor as EXECUTE IMMEDIATE (which is often abused by most people), or trying to use ref cursors within PL/SQL (which are more intended for 3rd party application layers).  The power of dynamic SQL is gained from using the DBMS_SQL package... as in the following simplistic example...
SQL> set serverout on
SQL> create or replace procedure run_query(p_sql IN VARCHAR2) is
  2    v_v_val     varchar2(4000);
  3    v_n_val     number;
  4    v_d_val     date;
  5    v_ret       number;
  6    c           number;
  7    d           number;
  8    col_cnt     integer;
  9    f           boolean;
10    rec_tab     dbms_sql.desc_tab;
11    col_num     number;
12    v_rowcount  number := 0;
13  begin
14    -- create a cursor
15    c := dbms_sql.open_cursor;
16    -- parse the SQL statement into the cursor
17    dbms_sql.parse(c, p_sql, dbms_sql.native);
18    -- execute the cursor
19    d := dbms_sql.execute(c);
20    --
21    -- Describe the columns returned by the SQL statement
22    dbms_sql.describe_columns(c, col_cnt, rec_tab);
23    --
24    -- Bind local return variables to the various columns based on their types
25
26    dbms_output.put_line('Number of columns in query : '||col_cnt);
27    for j in 1..col_cnt
28    loop
29      case rec_tab(j).col_type
30        when 1 then dbms_sql.define_column(c,j,v_v_val,2000); -- Varchar2
31        when 2 then dbms_sql.define_column(c,j,v_n_val);      -- Number
32        when 12 then dbms_sql.define_column(c,j,v_d_val);     -- Date
33      else
34        dbms_sql.define_column(c,j,v_v_val,2000);  -- Any other type return as varchar2
35      end case;
36    end loop;
37    --
38    -- Display what columns are being returned...
39    dbms_output.put_line('-- Columns --');
40    for j in 1..col_cnt
41    loop
42      dbms_output.put_line(rec_tab(j).col_name||' - '||case rec_tab(j).col_type when 1 then 'VARCHAR2'
43                                                                                when 2 then 'NUMBER'
44                                                                                when 12 then 'DATE'
45                                                       else 'Other' end);
46    end loop;
47    dbms_output.put_line('-------------');
48    --
49    -- This part outputs the DATA
50    loop
51      -- Fetch a row of data through the cursor
52      v_ret := dbms_sql.fetch_rows(c);
53      -- Exit when no more rows
54      exit when v_ret = 0;
55      v_rowcount := v_rowcount + 1;
56      dbms_output.put_line('Row: '||v_rowcount);
57      dbms_output.put_line('--------------');
58      -- Fetch the value of each column from the row
59      for j in 1..col_cnt
60      loop
61        -- Fetch each column into the correct data type based on the description of the column
62        case rec_tab(j).col_type
63          when 1  then dbms_sql.column_value(c,j,v_v_val);
64                       dbms_output.put_line(rec_tab(j).col_name||' : '||v_v_val);
65          when 2  then dbms_sql.column_value(c,j,v_n_val);
66                       dbms_output.put_line(rec_tab(j).col_name||' : '||v_n_val);
67          when 12 then dbms_sql.column_value(c,j,v_d_val);
68                       dbms_output.put_line(rec_tab(j).col_name||' : '||to_char(v_d_val,'DD/MM/YYYY HH24:MI:SS'));
69        else
70          dbms_sql.column_value(c,j,v_v_val);
71          dbms_output.put_line(rec_tab(j).col_name||' : '||v_v_val);
72        end case;
73      end loop;
74      dbms_output.put_line('--------------');
75    end loop;
76    --
77    -- Close the cursor now we have finished with it
78    dbms_sql.close_cursor(c);
79  END;
80  /
Procedure created.
SQL> exec run_query('select empno, ename, deptno, sal from emp where deptno = 10');
Number of columns in query : 4
-- Columns --
EMPNO - NUMBER
ENAME - VARCHAR2
DEPTNO - NUMBER
SAL - NUMBER
Row: 1
EMPNO : 7782
ENAME : CLARK
DEPTNO : 10
SAL : 2450
Row: 2
EMPNO : 7839
ENAME : KING
DEPTNO : 10
SAL : 5000
Row: 3
EMPNO : 7934
ENAME : MILLER
DEPTNO : 10
SAL : 1300
PL/SQL procedure successfully completed.
SQL>