Creating a 4-4-5 Time Period table

Question

Hello:
Very soon my company will be moving to a 4-4-5 reporting schedule.  Basically, what this means is that the first month of the quarter will have 4 weeks, the second will have 4 weeks, and the third will have 5 weeks.  Therefore, for the 2007 the dates for Jan, Feb and Mar will be as follows:
Jan - 1 - 27
Feb - 28 - 24
Mar - 25 - 31
Currently, I have an SSIS package creating a record for each day in the Time Dimension. 
Is there any T-SQL script out there that will help me build a Fiscal calendar such as the one described above?
Thank you!

Answer 1

The funky thing here is that 445, 445, 445, 445 (for quarters) leaves a couple days at the end of a year.   It's three 91-day quarters and 1 93-day quarter.
Here's the query i came up with.  Nothing succedes like brute force!
You can set any date for @dtFiscalYearStart and this query will work...that's the only variable.  no tables needed for this...just run it.
Code Snippet
declare @dtFiscalYearStart smalldatetime
, @dtFiscalYearEnd smalldatetime
, @iDaysInFiscalYear smallint
set @dtFiscalYEarStart = 'January 1, 2007'
set @dtFiscalYearEnd = dateadd(yyyy, 1, @dtFiscalYEarStart)
set @iDaysInFiscalYear = datediff(d, @DtFiscalYearStart, @dtFiscalYearEnd)
declare @Numbers table(Num int, dtTemp smalldatetime)
insert into @Numbers select 0, @dtFiscalYEarStart
declare @i tinyint
set @i = 0
while @i < 9
begin
insert into @Numbers select Num + power(2,@i)
, Dateadd(d, power(2,@i), dtTemp) from @Numbers
set @i = @i + 1
end
delete from @Numbers where dtTemp >= @dtFiscalYearEnd
select dtTemp
, Num + 1 as FiscalDay
, Dense_Rank() over (Partition by Num % (7) order by dtTemp) as FiscalWeek
, case
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 1 and 4 then 1
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 5 and 8 then 2
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 9 and 13 then 3
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 14 and 17 then 4
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 18 and 21 then 5
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 22 and 26 then 6
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 27 and 30 then 7
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 31 and 34 then 8
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 35 and 39 then 9
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 40 and 43 then 10
when Dense_Rank() over (Partition by Num % (7) order by dtTemp) between 44 and 47 then 11
else 12
end
as [FiscalMonth]
, case
when datediff(d, @dtFiscalYEarStart, dtTEmp) < (91*1) then 1
when datediff(d, @dtFiscalYEarStart, dtTEmp) < (91*2) then 2
when datediff(d, @dtFiscalYEarStart, dtTEmp) < (91*3) then 3
else 4
end
as FiscalQuarter
, datepart(dy,dtTemp) as CalendarDayOfYear
, Datepart(wk,dtTemp) as CalendarWeekOfYear
, Datepart(m,dtTemp) as CalendarMonth
, Datepart(q,dtTemp) as CalendarQuarter
from @Numbers
order by Dateadd(d, Num, @dtFiscalYearStart)