Creating an Invoice generator

Question

Hello, I'm new to apple and just started learning on how to use numbers.
But i'm having trouble with one very important formula for my business.
I'm trying to make a cell generate invoice numbers automatically when you save a spread sheet.
For example: if i would to open my invoice template, i would like it to number it 1, so that when i save it and give it a name. The next time i open it, it will number it 2.
Is this possible?
Because i know the date formula can do this automatically, but is there one for numbering too?

Answer 1

I just edited an old script.
--[SCRIPT numérote_Numbers ‘09]
Enregistrer le script en tant que Script, Application ou Progiciel : numérote_Numbers ‘09.xxx
déplacer l'e fichier créé dans le dossier
<VolumeDeDémarrage>:Utilisateurs:<votreCompte>:Bibliothèque:Scripts:Applications:Numbers:
Il vous faudra peut-être créer le dossier Numbers et peut-être même le dossier Applications.
Quand vous voudrez créer une facture, allez en
menu Scripts > numérote_Numbers ‘09
Le script créera une nouvelle facture à partir du modèle "ma_facture.nmbtemplate"
stocké dans le dossier "Modèles:Mes Modèles".
Il collera un numéro de facture qu'il stockera
dans le fichier "le_numéro.txt" rangé dans le "paquet" du modèle.
--=====
L'aide du Finder explique:
L'Utilitaire AppleScript permet d'activer le Menu des scripts :
Ouvrez l'Utilitaire AppleScript situé dans le dossier Applications/AppleScript.
Cochez la case "Afficher le menu des scripts dans la barre de menus".
+++++++
Save the script as Script, Application or Application Bundle: numérote_Numbers ‘09.xxx
Move the newly created application into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Numbers:
Maybe you would have to create the folder Numbers and even the folder Applications by yourself.
When you want to create a new invoice
Go to
menu Scripts > numérote_Numbers ‘09
The script will create a new invoice document from the template "ma_facture.nmbtemplate"
stored in "Templates:My templates"
It will paste an invoice number
and store it in the file "le_numéro.txt" in the template's package.
--=====
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox.
Yvan KOENIG, Vallauris (FRANCE)
4 mars 2008
5 juin 2009, revised for Numbers ‘09
property theApp : "Numbers"
--=====
on run
tell application "System Events" to if not (UI elements enabled) then set (UI elements enabled) to true (*
Active le GUI scripting
• Enable GUI scripting *)
my controleVersion()
set {chemin, numero} to my prepare()
set theNum to "invoice #" & text -5 thru -1 of ("0000" & numero) (* 5 digits number
• I put a leading string because Numbers drops the leading zeros *)
tell application "Numbers"
open chemin
activate
tell document 1 to tell sheet 1 to tell table 1 to set value of cell "A1" to theNum
end tell -- to theApp
end run
--=====
on getLocale(a, x)
tell application a to return localized string x
end getLocale
--=====
on prepare()
local factName, fichierNum, Templates_loc, myTemplates_loc, p2d, f, p2n, n
set factName to "ma_facture.nmbtemplate" (*
Adapter à vos besoins
• Put your preferred title *)
set fichierNum to "le_numéro.txt" (*
Adapter à vos besoins
• Put your preferred title *)
tell application theApp
set Templates_loc to localized string "Templates" (* nom local du dossier "Modèles" *)
set myTemplates_loc to localized string "My Templates" (* nom local du dossier "Mes Modèles" *)
end tell -- theApp
set p2d to (path to application support from user domain) as Unicode text
set f to p2d & "iWork:" & theApp & ":" & Templates_loc & ":" & myTemplates_loc & ":" & factName & ":"
set p2n to f & fichierNum
set f to f as alias
tell application "System Events"
if not (exists file p2n) then
make new file at end of f with properties {name:fichierNum}
write "100" to file p2n (*
mettez le numéro de départ de votre choix
• put the starting num fitting your needs*)
end if
end tell
set n to read file p2n
set n to ((n as integer) + 1) as text
write n to file p2n starting at 1
return {f, n}
end prepare
--=====
on controleVersion()
local v
try
set v to version of application theApp
on error
error "Doesn’t apply to Numbers ’08 !"
end try
end controleVersion
--=====
--[/SCRIPT]
Yvan KOENIG (from FRANCE vendredi 5 juin 2009 22:00:52)