CRM_ORDER_MAINTAIN - Create Service Request using IT_SERVICE_OS

Question

Hi,
I am using CRM_ORDER_MAINTAIN to create Service requests. To enter the Category (1 to 3) fields I am using the parameter IT_SERVICE_OS. But somehow it is not working. The Service request has been created but the Category is missing. The code used is given below. Please let me know where I am wrong.
    lw_subject-ref_handle   = 1.
    lw_subject-ref_handle_h = 1.
    lw_subject-katalogart = 'C'.
    lw_subject-codegruppe = 'ZSRCAT'.
    lw_subject-code       = 'LD02'.
    lw_subject-katalog_type = 'D'.
    CALL FUNCTION 'CRM_INTLAY_GET_HANDLE'
      IMPORTING
        ev_handle = lw_subject-ref_handle.
    lw_subject-mode       = gc_mode-create.
    INSERT lw_subject INTO TABLE lt_subject .
    CLEAR lw_osset.
    lw_osset-ref_handle      = 1.
    lw_osset-subject_profile = 'ZHRSERV'.
    lw_osset-profile_type    = 'A'.
    CALL FUNCTION 'CRM_SERVICE_OS_SET_DATA'
      EXPORTING
        is_srv_osset_com   = lw_osset
        iv_ref_handle      = lw_osset-ref_handle
        iv_ref_kind        = gc_object_ref_kind-orderadm_h
        it_srv_subject_com = lt_subject
      EXCEPTIONS
        error_occurred     = 1
        invalid_guid       = 2
        no_record_exist    = 3
        OTHERS             = 4.
    CALL FUNCTION 'CRM_SERVICE_OS_PUT_DATA'
      IMPORTING
        et_srv_osset_com = lt_service_os
        et_input_fields  = lt_input_fields_f.
    APPEND LINES OF lt_service_os TO gt_service_os.
    INSERT LINES OF lt_input_fields_f INTO TABLE gt_input_fields.
    CALL FUNCTION 'CRM_INTLAY_CLEAR_HANDLE'.
Thanks
Vinod

Answer 1

Hi Vinod,
In CRM4, I use something similiar to update categories through subject code.
Something like this:
*- Subject code create
*- Get Subject profile
CLEAR: ls_input_field_names, ls_input_field.
CALL FUNCTION 'CRM_ORDER_SERVICE_H_SELECT_CB'
  EXPORTING
    iv_process_type = iv_process_type
  IMPORTING
    es_service_h    = ls_service_h
  EXCEPTIONS
    entry_not_found = 1
    OTHERS          = 2.
*- Subject data
ls_subject-ref_handle = gv_handle.
ls_subject-katalogart = iv_katalogart.
ls_subject-codegruppe = iv_codegruppe.
ls_subject-code = iv_code.
ls_subject-mode = 'A'.
APPEND ls_subject TO lt_subject.
*- Osset data
ls_osset-ref_handle = gv_handle + 1.
ls_osset-subject = lt_subject.
ls_osset-subject_profile = ls_service_h-subject_profile.
ls_osset-profile_type = 'A'.
APPEND ls_osset TO ls_service_os-osset.
*- Service OS data
ls_service_os-ref_handle = gv_handle.
ls_service_os-ref_kind = 'A'.
APPEND ls_service_os TO gt_service_os.
*- Input fields
ls_input_field-ref_handle = gv_handle.
ls_input_field-ref_kind  = gc_object_kind-orderadm_h.
ls_input_field-objectname  = gc_object_name-service_os.
ls_input_field_names-fieldname = 'CODE'.
INSERT ls_input_field_names INTO TABLE ls_input_field-field_names.
ls_input_field_names-fieldname = 'CODEGRUPPE'.
INSERT ls_input_field_names INTO TABLE ls_input_field-field_names.
ls_input_field_names-fieldname = 'KATALOGART'.
INSERT ls_input_field_names INTO TABLE ls_input_field-field_names.
INSERT ls_input_field  INTO TABLE  gt_input_fields.
It works for me. Check if may help you a little more.
Kind regards,
Garcia