CRM_ORDER_MAINTAIN problems

Question

Hello.
I'm trying to insert new partner entries to the activity in a badi ORDER_SAVE (pf 00000026). How can I add these entries without loosing other entries with different partner functions?
I have tried to call fm CRM_ORDER_MAINTAIN and I'm able to insert new entries by following logic introduced in test program CRM_TEST_ORDER_MAINTAIN. When calling this fm all other entries are deleted.
What am I missing here?
Br, Johannes
Message was edited by: Johannes Mitronen

Answer 1

Hello Frederic!
Thank you for your answer. I finally managed to accomplish my goals. Other entries were deleted because I used an another fm with obviously wasn't the right one. Everything started to work when I also delete unwanted entries using fm CRM_ORDER_MAINTAIN.
Here's how I do it (if somebody else is struggling with similar kind of problems):
<b>1. Add new entries</b>
LOOP AT lt_entries INTO ls_entries.
    ADD 1 TO counter.
    CLEAR ls_new_partners.
    ls_new_partners-ref_guid = ls_orderadm_h-guid.
    ls_new_partners-ref_kind = ls_entries-ref_kind. "A
    ls_new_partners-kind_of_entry = 'C'.
    ls_new_partners-ref_partner_handle = counter.
    ls_new_partners-partner_fct = ls_entries-partner_fct.
    ls_new_partners-partner_no  = ls_entries-partner.
    ls_new_partners-display_type = 'BP'.
    ls_new_partners-no_type = 'BP'.
    INSERT ls_new_partners INTO TABLE lt_new_partners.
    CLEAR ls_input_fields.
    REFRESH ls_input_fields-field_names.
    ls_input_fields-ref_guid  = ls_new_partners-ref_guid.
    ls_input_fields-ref_kind = ls_new_partners-ref_kind. "A
    ls_input_fields-objectname = 'PARTNER'.
    MOVE-CORRESPONDING ls_new_partners TO ls_logical_key.
    ls_input_fields-logical_key = ls_logical_key.
    ls_input_field_name-fieldname = 'PARTNER_FCT'.
    INSERT ls_input_field_name INTO TABLE ls_input_fields-field_names.
    ls_input_field_name-fieldname = 'NO_TYPE'.
    INSERT ls_input_field_name INTO TABLE ls_input_fields-field_names.
    ls_input_field_name-fieldname = 'DISPLAY_TYPE'.
    INSERT ls_input_field_name INTO TABLE ls_input_fields-field_names.
    ls_input_field_name-fieldname = 'PARTNER_NO'.
    INSERT ls_input_field_name INTO TABLE ls_input_fields-field_names.
    ls_input_field_name-fieldname = 'KIND_OF_ENTRY'.
    INSERT ls_input_field_name INTO TABLE ls_input_fields-field_names.
    INSERT ls_input_fields INTO TABLE lt_input_fields.
  ENDLOOP.
  CALL FUNCTION 'CRM_ORDER_MAINTAIN'
    EXPORTING
      it_partner        = lt_new_partners
    CHANGING
      ct_input_fields   = lt_input_fields
    EXCEPTIONS
      error_occurred    = 1
      document_locked   = 2
      no_change_allowed = 3
      no_authority      = 4
      OTHERS            = 5.
<b>2. Delete entries</b>
LOOP AT lt_partner INTO ls_partner.
      MOVE-CORRESPONDING ls_partner TO ls_new_partners.
*     clear some fields for delete operation
      CLEAR ls_new_partners-ref_partner_handle.
      CLEAR ls_new_partners-partner_fct.
      INSERT ls_new_partners INTO TABLE lt_new_partners.
      CLEAR ls_input_fields.
      REFRESH ls_input_fields-field_names.
      ls_input_fields-ref_guid  = ls_new_partners-ref_guid.
      ls_input_fields-ref_kind = ls_new_partners-ref_kind.
      ls_input_fields-objectname = 'PARTNER'.
*     create logical key for delete operation
      CONCATENATE '0000' ls_partner-partner_fct ls_partner-partner_no INTO ls_input_fields-logical_key.
      CONCATENATE ls_partner-ref_no_type ls_partner-ref_no_type INTO id.
      WRITE id TO ls_input_fields-logical_key+28.
      ls_input_field_name-fieldname = 'PARTNER_FCT'.
      INSERT ls_input_field_name INTO TABLE ls_input_fields-field_names.
      INSERT ls_input_fields INTO TABLE lt_input_fields.
    ENDLOOP.
CALL FUNCTION 'CRM_ORDER_MAINTAIN'
    EXPORTING
      it_partner        = lt_new_partners
    CHANGING
      ct_input_fields   = lt_input_fields
    EXCEPTIONS
      error_occurred    = 1
      document_locked   = 2
      no_change_allowed = 3
      no_authority      = 4
      OTHERS            = 5.
Enjoy!
- Johannes