Don't want to abend program

Question

Hi,
During insertion from select, if DUPLICATE VALUE ON INDEX occours then i want to put the error message in a log file, instead of process aband and rest of insertion process continues.
regards
vk

Answer 1

I'm not sure is it acceptable time for 1 mln rows ?
SQL> set serveroutput on
SQL> set timing on
SQL> select count(1) from tst;
COUNT(1)
1
Elapsed: 00:00:00.00
SQL> declare
2 type cn is table of number(20) index by binary_integer;
3 nmbrs cn;
4 dml_error EXCEPTION;
5 PRAGMA exception_init(dml_error, -24381);
6 cursor ins_cur is select object_id from nc_objects;
7 begin
8 open ins_cur;
9 loop
10 fetch ins_cur bulk collect into nmbrs limit 100000;
11 if nmbrs.count>0 then
12 begin
13 forall i in nmbrs.first..nmbrs.last save exceptions
14 insert into tst values(nmbrs(i));
15 commit;
16 EXCEPTION
17 WHEN dml_error THEN
18 if (sql%BULK_EXCEPTIONS.COUNT>0) then
19 for i in 1..sql%BULK_EXCEPTIONS.COUNT loop
20 dbms_output.put_line('ID is ' || nmbrs(sql%BULK_EXCEPTIONS(i).ERROR_INDEX)
21 || '; Code is ORA-' || LPAD(sql%BULK_EXCEPTIONS(i).ERROR_CODE,5,'0'));
22 end loop;
23 end if;
24 END;
25 end if;
26 exit when ins_cur%NOTFOUND;
27 end loop;
28 close ins_cur;
29 end;
30 /
ID is 101; Code is ORA-00001
PL/SQL procedure successfully completed.
Elapsed: 00:05:47.06
SQL> select count(1) from tst;
COUNT(1)
934527
Elapsed: 00:00:00.01
Rgds.