Error Trapping

Question

Using Forms 6i Client/Server...
Does anyone have a generic error handling routine for Forms?
I want to trap Forms and DB error messages in on-error/on-message triggers to display more user-friendly messages. I also want to retain message bultins in their present format.
Ideally the code will be in a PL/SQL library that I can reference in the triggers.
I know about the dbms_error_code/erroc_code/text built ins but I am having trouble differentiating them!
At the moment, everything seems to be picked up in the on-error trigger as a dbms_error_code!
EG.
BEGIN
IF dbms_error_code IS NOT NULL
THEN
--FLAG DB ERROR
ELSIF error_code IS NOT NULL
THEN
-- FLAG FORM ERROR
END IF;
END;
always flags a db error!

Answer 1

Here is our PLL_ON_ERROR pll library trigger. It has some site-specific code, but the dbms_error_text handling should work well for you. The PLL_MsgC and MsgE are just Message commands followed by a Raise FormTrigger_Failure; The _MsgE sets the background color red on a specific field.
PROCEDURE PLL_ON_ERROR(ERR_IN IN NUMBER   DEFAULT NULL,
                       MSG_IN IN VARCHAR2 DEFAULT NULL) IS           --*
-- PLL_On_Error overrides default form error processing.  Usually
-- this is called from a form-level on-error trigger with the command
--    PLL_ON_ERROR;
-- However, if the form requires additional error processing, the
-- following method can be used:
DECLARE
  Err_Code NUMBER(5)     := ERROR_CODE;
  MSG     VARCHAR2(150)
          := SUBSTR('   '||ERROR_TYPE||'-'||TO_CHAR(Err_Code)||': '
                                     ||ERROR_TEXT,1,150);
BEGIN
  IF Err_Code=<special value here> THEN
      PLL_MSGE('   <special message, etc. here> ');
  ELSE
    PLL_ON_ERROR(Err_Code,MSG);
  END IF;
END;
  Err_Code NUMBER(5)     := NVL(ERR_IN,ERROR_CODE);
  Err_Text VARCHAR2(100) := ERROR_TEXT;
  MSG      VARCHAR2(150) := NVL(MSG_IN,SUBSTR('   '||ERROR_TYPE||'-'
                           ||TO_CHAR(Err_Code)||': '||Err_Text,1,150));
  DBMS_TXT VARCHAR2(500);
BEGIN
  IF Err_Code IN (40401,40405,     --No changes to save/apply
                  40100,40352) THEN --at first/last record
    MESSAGE(MSG,NO_ACKNOWLEDGE); -- Don't raise Form_Trigger_Failure
  ELSIF Err_Code=41049 THEN
    PLL_MSGC('   0017  DELETE IS NOT ALLOWED');
  ELSIF Err_Code=41051 THEN
    PLL_MSGC('   0016  INSERT IS NOT ALLOWED');
  ELSIF Err_Code=40733 --pl/sql built-in <xxx> failed.
    AND INSTR(MSG,'SHOW_LOV')>0
    AND (   GET_BLOCK_PROPERTY(NAME_IN('SYSTEM.TRIGGER_BLOCK'),
              UPDATE_ALLOWED)='FALSE'
         OR GET_BLOCK_PROPERTY(NAME_IN('SYSTEM.TRIGGER_BLOCK'),
              INSERT_ALLOWED)='FALSE'
           AND NAME_IN('SYSTEM.RECORD_STATUS')='NEW'
         OR DBMS_ERROR_CODE = -54 ) then -- -54=Locked record
    -- Dsply-only user selected a val from LOV. Prevents double msgs
    RAISE FORM_TRIGGER_FAILURE;
  --  Display Forms error along with
  --  database error.  Helps determine the "real" problem.
  ELSIF Err_Code IN
     (40102,       --Record must be entered or deleted first
      40501,       --unable to reserve rec for updt/delete (ORA-00054)
      41008,       --undefined fn key(dbms_txt=ora-01003:no stmt parsed)
      47013,47021) --no such parameter errs.
    THEN -- display msg on status line.  Don't check dbms_txt below
    PLL_MSGC(MSG);
  --  Format date input error msg
  Elsif Err_Code between 50002 and 50026
    and Err_Code - 50000 in(2,3,4,12,17,18,19,21,22,23,25,26) then
    -- 50002: Month must be between 1 and 12.
    -- 50003: Year must be 00-99 or 1000-4712
    -- 50004: Day must be between 1 and last of month.
    -- 50012: Date must be entered in a format like <fxMMDDRR>
    -- 50017,18,19: Hour,Min,Sec must be between 0 and 23,59,59.
    -- 50025: Date/time must be entered in a format like <xxyytttt>
    -- 50026: same as 50012 and 50025 with <yyyy> year.
    Declare
      Fmt varchar2(30)
        := replace(replace(replace(replace(
             upper(GET_ITEM_PROPERTY(
                                     Name_in('SYSTEM.TRIGGER_ITEM'),
                                     FORMAT_MASK)),
            'RR','YY'),'FX',''),'HH24','hh'),'MI','mm');
      Itm  varchar2(30);
      Msg1 varchar2(100);
      Msg2 varchar2(30);
    Begin
      Itm := Substr(Name_in('SYSTEM.TRIGGER_ITEM'),
                    instr(Name_in('SYSTEM.TRIGGER_ITEM'),'.')+1);
      Itm := replace(Itm,'_',' ');
      Msg1 := '   0012  Invalid value in '|| Itm ||'.   ';
      If fmt = 'YY' then
        PLL_MSGE(Msg1||'Enter a two-digit year between 00 and 99.');
      Else
        Msg2 := substr(Err_Text,1,instr(Err_Text,' ')-1);
        If upper(Msg2) in ('MONTH','DAY','YEAR','HOUR','MINUTES') then
          Msg1 := Msg1 ||'Error in ' || Msg2 ||' --  ';
        end if;
        PLL_MSGE(Msg1 || 'Format is ' || Fmt );
      End if;
    End;
  ELSIF Err_Code BETWEEN 40200 AND 40299 --field errors detected by Form
     OR Err_Code = 40108 -- No such form
     OR Err_Code > 50000 THEN
    PLL_MSGE(MSG); --sets erroritem visual attribute
  ELSE -- all other messages
    -- check database error message --
    DBMS_TXT := SUBSTR(DBMS_ERROR_TEXT,1,500);
    if  DBMS_TXT is not null
    and substr(DBMS_TXT,5,5)
      not in('00000',
             '01403') then --1403=no data found
      -- Show entire msg, add new_line chars.
      DBMS_TXT := replace(DBMS_TXT,'ORA-',chr(10)||'ORA-');
      DBMS_TXT := replace(DBMS_TXT,' '||chr(10), chr(10));
      -- show MSG and DBMS_TXT both as an alert --
      PLL_ALERT( ltrim(MSG) || DBMS_TXT );
      Raise Form_Trigger_Failure;
    else
      PLL_MSGC(MSG);
    End if;
  END IF;
END PLL_ON_ERROR;And PLL_ALERT is as follows:
PROCEDURE PLL_ALERT(MSG IN VARCHAR2) IS
-- Alert_Message can be up to 200 characters.
-- Message can be up to 255.
-- Displays an alert message.  If the form has an alert named ALERT_001
-- and the message is not more than 200 characters, then that is used.
-- Otherwise, the default "stacked message" alert method is used by
-- setting two successive messages.  An alert can display a maximum of
-- 200 characters while the stacked messages can display 255.  If Msg
-- is longer than 255, then this loops to display all the message.
  Alert_ID Alert;
  Btn      Number;
  P        pls_integer := 1;
  L        pls_integer := nvl(length(msg),0);
  mtxt     varchar2(300);
  ltrm     boolean := true;
  -- This function ensures new line characters are handled properly.
  -- replaces linefeed [chr(10)] and Carriage Return [chr(13)] chars
  -- as necessary depending on where form is running (Web
  -- or client/server) and whether using an Alert or stacked message.
  function trans(m_in in varchar2,using_alert boolean := False)
       return varchar2 is
    m  varchar2(300) := m_in;
  begin
    -- Modify end-of-line characters, depending on WEB or client/server
    -- and whether using alert or stacked message.
    If Get_Application_Property(User_Interface) = 'WEB' then
      if using_alert then --web alert: chr(10) is new line
        m := replace(m, chr(13), chr(10));
        m := replace(m, chr(10)||chr(10), chr(10));
      else -- web, message: chr(138) is new line
        m := translate(m, chr(10)||chr(13), chr(138)||chr(138) );
        m := replace(m, chr(138)||chr(138), chr(138));
      end if;
    elsif not using_alert then
      -- Client/server:  If using alert, no change required
      -- Client/server message: chr(13) is new line
      m := replace(m, chr(10), chr(13));
      m := replace(m, chr(13)||chr(13), chr(13));
    end if;
    -- ltrim first line only
    if ltrm then
      m := ltrim(m);
      ltrm := false;
    end if;
    return m;
  end trans;
BEGIN
  If L <= 200 then
    Alert_ID := Find_Alert('ALERT_001');
    If not ID_Null(Alert_ID) then
      Set_Alert_Property(Alert_ID,ALERT_MESSAGE_TEXT,trans(Msg,True));
      Btn := Show_Alert(Alert_ID);
      return;
    end if;
  end if;
  if L <= 255 then
    Message(trans(msg));
  else
    loop exit when P > L;
      If L - P <= 254 then
        mtxt := substr(msg,p);
        P := P + 255;
      Else
        mtxt := substr(msg,p,252) || '...';
        P := P + 252;
      End if;
      Message(trans(mtxt));
    end loop;
  end if;
  Message(' ',no_acknowledge); --forces message into an alert box.
End PLL_ALERT;