Executing BAPI_PO_CREATE1 in a loop results in multiple success messages

Question

Hi all,
I have a process where I need to create multiple POs with one item each. For creating the POs I use BAPI_PO_CREATE1. The creation itself works fine and created POs are also correct.
But what is a bit confusing is the content of the RETURN table of the BAPI. From the second created PO on I also get ALL messages of the previously created POs although I have a COMMIT WORK AND WAIT after each creation and the return table is always empty when executing the BAPI.
Example:
I need to create two POs.
First run of the BAPI_PO_CREATE: PO A is created and return table has success message "PO A successfully created"
Second run of the BAPI_PO_CREATE: PO B is created and return table has two success messages: "PO A successfully created" and "PO B successfully created"
But for the second run I also would expect to get only one success message.
Why do I get too many messages? Or do I need to initilize the BAPI somehow?
By the way, I have the same problem with BAPI_PO_CHANGE.
regards
René

Answer 1

Hi,
so again: the return table is cleared/refreshed all times when executing the loop and a commit is done!
Unfortunately the whole coding is implemented to the SAP AIF so the AIF is doing the loops. But in debugging I clearly see that the return table is empty before executing the BAPI.
Here is the coding. The AIF calls the here described function module in a loop and executes a commit work and wait after each call of the FM.
FUNCTION POST_PURCHASE_ORDER.
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(TESTRUN) TYPE  C
*"     REFERENCE(HASH_TAB) TYPE  /AIF/HASHTAB_T OPTIONAL
*"     REFERENCE(IDX_TAB) TYPE  /AIF/IDXTAB_T OPTIONAL
*"  TABLES
*"      RETURN_TAB STRUCTURE  BAPIRET2
*"  CHANGING
*"     REFERENCE(DATA)
*"     REFERENCE(CURR_LINE)
*"     REFERENCE(CURR_DATA)
*"     REFERENCE(SUCCESS) TYPE  /AIF/SUCCESSFLAG
*"     REFERENCE(OLD_MESSAGES) TYPE  BAL_T_MSG
  DATA: lt_po_items        TYPE TABLE OF bapimepoitem,
        lt_po_itemsx       TYPE TABLE OF bapimepoitemx,
        lt_bapiparex       TYPE TABLE OF bapiparex,
        lt_po_conditionx   TYPE TABLE OF bapimepocondx,
        lt_po_header_texts TYPE TABLE OF bapimepotextheader,
        lt_po_item_texts   TYPE TABLE OF bapimepotext,
        ls_po_headerx      TYPE bapimepoheaderx,
        ls_po_headerx_cust TYPE bapi_te_mepoheaderx,
        ls_po_itemx        TYPE bapimepoitemx,
        ls_po_condition    TYPE bapimepocond,
        ls_po_conditionx   TYPE bapimepocondx,
        l_testrun          TYPE bapiflag-bapiflag.
  CHECK curr_line IS NOT INITIAL.
  REFRESH: return_tab[].
  CLEAR: return_tab[].
  l_testrun = testrun.
* Get X-structures for PO header
  PERFORM fill_x_structure USING curr_line-po_header 0 CHANGING ls_po_headerx.
* Create PO Header Custom Fields.
  PERFORM fill_bapiparex USING curr_line-po_header_cust space
                      CHANGING lt_bapiparex[] return_tab[].
* Get X-structures for PO ExtensionIn fields and post them to ExtensionIn as well
  PERFORM fill_x_structure USING curr_line-po_header_cust 0 CHANGING ls_po_headerx_cust.
  PERFORM fill_bapiparex USING ls_po_headerx_cust space
                      CHANGING lt_bapiparex[] return_tab[].
* Get X-structure for PO item
  curr_line-po_item-info_upd = 'A'.
  curr_line-po_item-po_price = '1'.
  PERFORM fill_x_structure USING curr_line-po_item 1 CHANGING ls_po_itemx.
  ls_po_itemx-po_item        = curr_line-po_item-po_item.
  curr_line-po_item-po_price = space.
  curr_line-po_item-info_upd = space.
  APPEND curr_line-po_item  TO lt_po_items.
  APPEND ls_po_itemx TO lt_po_itemsx.
* Get X-structures for PO conditions
  IF NOT curr_line-po_conditions IS INITIAL.
    LOOP AT curr_line-po_conditions INTO ls_po_condition.
      CLEAR ls_po_conditionx.
      ls_po_conditionx-itm_number = ls_po_condition-itm_number.
      PERFORM fill_x_structure_2 USING ls_po_condition 3 0
                              CHANGING ls_po_conditionx.
      APPEND ls_po_conditionx TO lt_po_conditionx.
    ENDLOOP.
  ENDIF.
* Get header and item texts
  APPEND curr_line-po_header_text TO lt_po_header_texts.
  APPEND curr_line-po_item_text   TO lt_po_item_texts.
* Execute BAPI_PO_CREATE1
  CALL FUNCTION 'BAPI_PO_CREATE1'
    EXPORTING
      poheader         = curr_line-po_header
      poheaderx        = ls_po_headerx
      testrun          = l_testrun
      no_price_from_po = c_checked
    IMPORTING
      exppurchaseorder = curr_line-po_number_return
    TABLES
      return           = return_tab
      poitem           = lt_po_items
      poitemx          = lt_po_itemsx
      pocond           = curr_line-po_conditions
      pocondx          = lt_po_conditionx
      extensionin      = lt_bapiparex
      potextheader     = lt_po_header_texts
      potextitem       = lt_po_item_texts
    EXCEPTIONS
      error_message    = 1.
  IF sy-subrc = 1.
    IF NOT sy-msgid IS INITIAL
      AND NOT sy-msgty IS INITIAL
      AND NOT sy-msgno IS INITIAL.
      PERFORM util_add_msg USING sy-msgty sy-msgid sy-msgno sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4 CHANGING return_tab[].
    ENDIF.
  ENDIF.
ENDFUNCTION.