F4 Help for the selection screen field

Question

Hi Gurus,
I have to display F4 help for a selection screen field. i am using following code:
    CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
         EXPORTING
              retfield        = 'CODE'
              dynpprog        = lw_repid
              dynpnr          = sy-dynnr
              VALUE_ORG       = 'S'
         TABLES
              value_tab       = gi_text
             field_tab       = li_fields_tab
              return_tab      = pi_return_tab
         EXCEPTIONS
              parameter_error = 1
              no_values_found = 2
              OTHERS          = 3.
My internal table gi_emp has two fields CODE & TEXT. When i select 1 particular value, it returns the CODE value in the pi_return_tab table.
But my requirement is i have to capture the corresponding TEXT value for the Returned CODE. Ex: following is the F4 help being displayed: -
001    test
001    test1
but is i select code 001(First Value), i also need to capture it's corresponding Text value. In return table pi_return_tab i have only Code value.
Please help me out.
Note: Based on return code i can't search into the internal table gi_code, because as shown in the example, code has multiple text.

Answer 1

Sachin,
I think this is what you need. The following code will return the key and the text (OR any other columns), if both columns are in the selection screen the selected values (both columns) will also be passed to the corresponding parameters. If you only need the text to be in the return table and not passed to the selection screen then set the parameter for text with NO-DISPLAY option.
REPORT zktest01 .
DATA :
  BEGIN OF value_tab OCCURS 0,
    field  LIKE e070-trkorr,
    text   LIKE e07t-as4text,
  END OF value_tab.
DATA: t_fldtab LIKE dfies OCCURS 0 WITH HEADER LINE,
      t_rettab LIKE ddshretval OCCURS 0 WITH HEADER LINE,
      t_dynmap LIKE dselc OCCURS 0 WITH HEADER LINE.
PARAMETERS : p_field  LIKE value_tab-field,
             p_text   LIKE value_tab-text. "NO-DISPLAY.
INITIALIZATION.
  t_fldtab-tabname   = 'VALUE_TAB'.
  t_fldtab-fieldname = 'FIELD'.
  t_fldtab-langu     = 'E'.
  t_fldtab-position  = 1.
  t_fldtab-offset    = 0.
  t_fldtab-fieldtext = 'Key'.
  t_fldtab-reptext   = 'Key'.
  t_fldtab-leng      = 20.
  t_fldtab-intlen    = 20.
  t_fldtab-outputlen = 20.
  t_fldtab-datatype  = 'CHAR'.
  t_fldtab-inttype   = 'C'.
  t_fldtab-headlen   = 20.
  t_fldtab-keyflag   = 'X'.
  t_fldtab-lowercase = ' '.
  APPEND t_fldtab.
  t_fldtab-tabname   = 'VALUE_TAB'.
  t_fldtab-fieldname = 'TEXT'.
  t_fldtab-position  = 2.
  t_fldtab-offset    = 20.
  t_fldtab-fieldtext = 'Text'.
  t_fldtab-reptext   = 'Text'.
  t_fldtab-leng      = 60.
  t_fldtab-intlen    = 60.
  t_fldtab-outputlen = 60.
  t_fldtab-headlen   = 60.
  t_fldtab-keyflag   = ' '.
  t_fldtab-lowercase = ' '.
  APPEND t_fldtab.
  value_tab-field = '101'.
  value_tab-text = 'dddd'.
  APPEND value_tab.
  value_tab-field = '202'.
  value_tab-text = 'aaaa'.
  APPEND value_tab.
  t_dynmap-fldname = 'FIELD'.
  t_dynmap-dyfldname = 'P_FIELD'.
  APPEND t_dynmap.
  t_dynmap-fldname = 'TEXT'.
  t_dynmap-dyfldname = 'P_TEXT'.
  APPEND t_dynmap.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_field.
  CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
       EXPORTING
            retfield        = 'FIELD'
            dynpprog        = 'ZKTEST01'
            dynpnr          = '1000'
            dynprofield     = 'P_FIELD'
            value_org       = 'S'
       TABLES
            field_tab       = t_fldtab
            value_tab       = value_tab
            return_tab      = t_rettab
            dynpfld_mapping = t_dynmap
       EXCEPTIONS
            parameter_error = 1
            no_values_found = 2
            OTHERS          = 3.
  IF sy-subrc EQ 0.
  ENDIF.
START-OF-SELECTION.
Jeffrey Satriadi