Failed to Run OLE Excel program in background JOB (SM36)

Question

Please help.
I have write a program to use OLE to create a Excel file.
The program can run successful in front end workstation. However, when I run the program in background job by SM36.
The statement "CREATE OBJECT EXCEL 'EXCEL.APPLICATION'" return with error "SY-SUBRC = 2".
How can I solve it ?
Can OLE Excel be run on background job ?
Thanks so much,
Mark

Answer 1

Hi Mark:
Your need is a very common one. I also was asked to generate an Excel in Background.
It is not possible to work with OLE in background mode.
The reason is: In background mode there is no presentation server. OLE is executed in presentation server.
Below I paste the code I wrote to solve my problem.
This class sends a mail with an excel attached. The Excel content will be the internal table you pass to the class. But the Excel is not binary, it is a plain text file, separated by tabulators. Anyway, when you open it with Excel, the columns are properly shown.
Sorry. Comments are in spanish, I don't have time to translate it.
I kindly ask to everybody which want to use it to keep my name in the code.
* Autor: Jordi Escoda, 30/10/2008.
* Descripción: Esta clase genera un correo electrónico destinado a
*  una persona, adjuntando el contenido de una tabla interna como
*  Excel (campos separados por tabuladores).
*  La virtud de esta clase es su sencillez de utilización. Para lanzar
*  el mail con el excel adjunto basta con declarar la tabla interna,
*  llenarla, colocar el asunto del mensaje, el destinatario, el nombre
*  del excel adjunto, y pasar la tabla interna.
* Ejemplo de utilización:
*  DATA: lc_mail TYPE REF TO cl_mail_builder_xls_attach.
*  DATA: lt_anla TYPE STANDARD TABLE OF anla.
*    SELECT * INTO TABLE lt_anla  FROM anla.
*    CREATE OBJECT lc_mail.
*    CALL METHOD lc_mail->set_subject( 'Excel adjunto' ).
*    CALL METHOD lc_mail->set_recipient( 'XXX@XXXDOTCOM' ).
*    CALL METHOD lc_mail->set_attach_filename( 'ANLA' ).
*    APPEND 'Cuerpo del mensaje' TO  lt_body.
*    APPEND 'Saludos cordiales' TO  lt_body.
*    CALL METHOD lc_mail->set_bodytext( lt_body ).
*    CALL METHOD lc_mail->set_attach_table( lt_anla ).
*    CALL METHOD lc_mail->send( ).
*       CLASS cl_mail_builder_xls_attach DEFINITION
CLASS cl_mail_builder_xls_attach DEFINITION.
  PUBLIC SECTION.
    METHODS: set_subject
                           IMPORTING im_subject TYPE so_obj_des,
             set_bodytext
                           IMPORTING im_body TYPE bcsy_text,
             set_recipient
                           IMPORTING im_recipient TYPE ad_smtpadr,
             set_attach_table
                           IMPORTING im_table TYPE ANY TABLE,
             set_attach_filename
                           IMPORTING im_attach_name TYPE sood-objdes,
             send.
  PRIVATE SECTION.
    CONSTANTS:
      c_tab  TYPE c VALUE cl_bcs_convert=>gc_tab,
      c_crlf TYPE c VALUE cl_bcs_convert=>gc_crlf,
      c_singlequote TYPE c VALUE '.
    DATA: l_recipient_addr TYPE ad_smtpadr.
    DATA: send_request   TYPE REF TO cl_bcs,
          document       TYPE REF TO cl_document_bcs,
          recipient      TYPE REF TO if_recipient_bcs,
          bcs_exception  TYPE REF TO cx_bcs.
    DATA: binary_content TYPE solix_tab,
          size           TYPE so_obj_len.
    DATA: l_string TYPE string,
          l_body_text TYPE bcsy_text,
          l_subject TYPE so_obj_des,
          l_attach_name TYPE sood-objdes.
    METHODS: create_binary_content,
             get_dataelement_medium_text
                    IMPORTING im_table_name TYPE tabname
                              im_field_name TYPE fieldname
                    EXPORTING ex_medium_text TYPE scrtext_m.
ENDCLASS.                    "cl_mail_builder_xls_attach DEFINITION
*       CLASS cl_mail_builder_xls_attach IMPLEMENTATION
CLASS cl_mail_builder_xls_attach IMPLEMENTATION.
  METHOD set_bodytext.
    l_body_text[] = im_body[].
  ENDMETHOD.                    "add_bodytext
  METHOD set_subject.
    l_subject = im_subject.
  ENDMETHOD.                    "add_subject
  METHOD set_attach_filename.
    l_attach_name = im_attach_name.
  ENDMETHOD.                    "add_subject
  METHOD set_recipient.
    l_recipient_addr = im_recipient.
  ENDMETHOD.                    "add_subject
  METHOD set_attach_table.
*   Rellena en un string el contenido de la tabla interna recibida
    DATA: ref_to_struct  TYPE REF TO cl_abap_structdescr.
    DATA: my_like TYPE fieldname,
          nombretabla TYPE tabname,
          nombrecampo TYPE fieldname,
          texto_mediano TYPE scrtext_m.
    DATA: l_idx TYPE i,
          l_valorcampo(16) TYPE c,
          l_long TYPE i.
    FIELD-SYMBOLS: <fs_linea> TYPE ANY,
                   <fs_campo> TYPE ANY.
    FIELD-SYMBOLS: <comp_descr> TYPE abap_compdescr.
    CHECK NOT im_table[] IS INITIAL.
*   Línea con los nombres de las columnas.
    CLEAR l_string.
    LOOP AT im_table ASSIGNING <fs_linea>.
*     Toma los atributos del componente
      ref_to_struct  =
                 cl_abap_structdescr=>describe_by_data( <fs_linea> ).
      LOOP AT ref_to_struct->components ASSIGNING <comp_descr>.
        ASSIGN COMPONENT <comp_descr>-name
                            OF STRUCTURE <fs_linea> TO <fs_campo>.
*       Obtenemos el origen de donde proviene (like). Ej:BKPF-BUDAT
        DESCRIBE FIELD <fs_campo> HELP-ID my_like.
        SPLIT my_like AT '-' INTO nombretabla nombrecampo.
        CALL METHOD get_dataelement_medium_text
          EXPORTING
            im_table_name  = nombretabla
            im_field_name  = nombrecampo
          IMPORTING
            ex_medium_text = texto_mediano.
        IF texto_mediano IS INITIAL.
          CONCATENATE l_string <comp_descr>-name INTO l_string.
        ELSE.
          CONCATENATE l_string texto_mediano INTO l_string.
        ENDIF.
        AT LAST.
          CONCATENATE l_string c_crlf INTO l_string.
          EXIT.
        ENDAT.
        CONCATENATE l_string c_tab INTO l_string.
      ENDLOOP.
      EXIT.
    ENDLOOP.
*   Contenido de la tabla
    LOOP AT im_table ASSIGNING <fs_linea>.
*     Toma los atributos del componente
      ref_to_struct  =
                 cl_abap_structdescr=>describe_by_data( <fs_linea> ).
      LOOP AT ref_to_struct->components ASSIGNING <comp_descr>.
*       Asignamos el componente ue tratamos, para obtener
*       el valor del mismo
        ASSIGN COMPONENT <comp_descr>-name OF STRUCTURE <fs_linea>
                                        TO <fs_campo>.
        CASE <comp_descr>-type_kind.
          WHEN 'P'. "Packed Number
*           Convierte a caracter
            WRITE <fs_campo> TO l_valorcampo.
            CONCATENATE l_string l_valorcampo INTO l_string.
          WHEN OTHERS.
            l_long = STRLEN( <fs_campo> ).
            IF l_long > 11 AND <fs_campo> CO ' 0123456789'.
*             El Excel muestra un número tal como 190000000006
*             en formato 1,9E+11.
*             Para eviarlo, los números de más de 11 dígitos los
*             concatenamos con comillas simples.
              CONCATENATE l_string c_singlequote
                          <fs_campo> c_singlequote INTO l_string.
            ELSE.
              CONCATENATE l_string <fs_campo> INTO l_string.
            ENDIF.
        ENDCASE.
        AT LAST.
*         Añade CRLF
          CONCATENATE l_string c_crlf INTO l_string.
          EXIT.
        ENDAT.
*       Añade tabulador
        CONCATENATE l_string c_tab INTO l_string.
      ENDLOOP.
    ENDLOOP.
    create_binary_content( ).
  ENDMETHOD.                    "set_attach_table
  METHOD create_binary_content.
    DATA: l_size TYPE so_obj_len.
*   convert the text string into UTF-16LE binary data including
*   byte-order-mark. Mircosoft Excel prefers these settings
*   all this is done by new class cl_bcs_convert (see note 1151257)
    TRY.
        cl_bcs_convert=>string_to_solix(
          EXPORTING
            iv_string   = l_string
            iv_codepage = '4103'  "suitable for MS Excel, leave empty
            iv_add_bom  = 'X'     "for other doc types
          IMPORTING
            et_solix  = binary_content
            ev_size   = size ).
      CATCH cx_bcs.
        MESSAGE e445(so).
    ENDTRY.
  ENDMETHOD.                    "create_binary_content
  METHOD send.
    DATA: l_sent_to_all TYPE os_boolean.
    TRY.
*       create persistent send request
        send_request = cl_bcs=>create_persistent( ).
*       create and set document with attachment
*       create document object
        document = cl_document_bcs=>create_document(
          i_type    = 'RAW'
          i_text    = l_body_text
          i_subject = l_subject ).
*       add the spread sheet as attachment to document object
        document->add_attachment(
          i_attachment_type    = 'xls'
          i_attachment_subject = l_attach_name
          i_attachment_size    = size
          i_att_content_hex    = binary_content ).
*       add document object to send request
        send_request->set_document( document ).
*       add recipient (e-mail address)
        recipient =
           cl_cam_address_bcs=>create_internet_address(
                                      l_recipient_addr ).
*       add recipient object to send request
        send_request->add_recipient( recipient ).
*       send document
        l_sent_to_all = send_request->send(
                             i_with_error_screen = 'X' ).
        COMMIT WORK.
        IF l_sent_to_all IS INITIAL.
          MESSAGE i500(sbcoms) WITH l_recipient_addr.
        ELSE.
          MESSAGE s022(so).
        ENDIF.
      CATCH cx_bcs INTO bcs_exception.
        MESSAGE i865(so) WITH bcs_exception->error_type.
    ENDTRY.
  ENDMETHOD.                    "lcl_mail_xls_attachment
  METHOD get_dataelement_medium_text.
    DATA: lt_fld_info TYPE STANDARD TABLE OF dfies,
      wa_fld_info TYPE dfies.
*   Busca en el diccionario los datos del campo
    CALL FUNCTION 'DDIF_FIELDINFO_GET'
      EXPORTING
        tabname        = im_table_name
        fieldname      = im_field_name
        langu          = sy-langu
      TABLES
        dfies_tab      = lt_fld_info
      EXCEPTIONS
        not_found      = 1
        internal_error = 2
        OTHERS         = 3.
    CLEAR ex_medium_text.
    IF sy-subrc = 0.
      READ TABLE lt_fld_info INDEX 1 INTO wa_fld_info.
*     Si lo ha podido tomar del diccionario...
      IF NOT wa_fld_info-scrtext_m IS INITIAL.
*       Toma el nombre del nombre de campo del diccionario
        ex_medium_text = wa_fld_info-scrtext_m.
      ENDIF.
    ENDIF.
  ENDMETHOD.                    "get_dataelement_medium_text
ENDCLASS.                    "cl_mail_builder_xls_attach IMPLEMENTATION