Feature Request: Multiple Email Reply

Question

I've spent a few minutes hunting around the Apple.com website trying to find/search for a way to provide feedback for Mail. There doesn't appear to be such a beast, so I thought I would post it here.
In other email programs I have used over the years, I could select more than one email message, select reply, and all of the selected emails would appear in the one message, which was handy when you were replying to several messages to the same person at once.
Yes, I could forward them, but It would be nice to just be able to reply to them. So, Apple, there you have my suggestion.

Answer 1

Someone else looked for this a while back, so I wrote them this little script. Let me know if you have problems with it.
AK
<pre style="font-family: 'Monaco', 'Courier New', Courier, monospace; overflow:auto; color: #222; background: #DDD; padding: 0.2em; font-size: 10px; width:400px">(*Save the script in the Library/Scripts/Applications/Mail folder of your home directory. With several messages selected in Mail run
the script from the Scripts menu item on the menu bar. It will generate a new message with the sender of each of the selected
mails asa recipient, and the subject of the first selected mail as subject. Non-adjacent messages can be selected with Command-click.
AK Sep 2005 [email protected] *)
using terms from application "Mail"
on perform mail action with messages TheMail
tell application "Mail"
set theSubject to ""
repeat with ThisMail in TheMail
set TheName to extract name from sender of ThisMail
set TheAddress to extract address from sender of ThisMail
if theSubject is "" then -- set subject, make message 1st time through
set theSubject to subject of ThisMail
if theSubject does not start with "Re:" then set theSubject to "Re: " & theSubject
set newMessage to make new outgoing message with properties {subject:theSubject}
end if
tell newMessage
make new to recipient at end of to recipients with properties {name:TheName, address:TheAddress}
end tell
end repeat
tell newMessage to set visible to true
end tell
end perform mail action with messages
end using terms from
using terms from application "Mail"
on run
tell application "Mail" to set sel to selection
tell me to perform mail action with messages (sel)
end run
end using terms from
</pre>