Follow-up question for Chris H on longtext in BDC for IW31

Question

Chris -
Here's the relevant part of my code:
PERFORM DYNPRO USING:
'X' 'SAPLCOIH'          '3000',            "
' ' 'CAUFVD-KTEXT   '   SCRN_PROBLEM1,     " 1st line problem text
' ' 'CAUFVD-ANLZU   '   CAUFVD-ANLZU,      " System condition
' ' 'BDC_OKCODE'       '=LTXK'.            "
LOOP AT i_txt INTO wa_txt.
  v_txtln_ctr_n = sy-tabix + 2.    " Chris - note that I'm bumping to "3" here
  v_txtln_ctr_c = v_txtln_ctr_n.
  CONCATENATE 'RSTXT-TXLINE('
              v_txtln_ctr_c
         INTO v_bdc_txtln_lit.
  CONDENSE v_bdc_txtln_lit NO-GAPS.
  PERFORM DYNPRO USING:
    'X' 'SAPLSTXX'          '1100',              "
    ' ' v_bdc_txtln_lit     wa_txt,              " line of problem text
    ' ' 'BDC_OKCODE'        '=ENTR'.             "
ENDLOOP.
This actually works - it creates an order in which the long text begins with what is in the variable SCRN_PROBLEM1 and continues with what is in i_txt concatenated together.  So I get, for example:
"This is the short description. a b c d e"
where:
scrn_problem1 = 'This is the short description'
row 1 of i_txt = 'a'
row 2 of i_txt = 'b'
row 3 of i_txt = 'c'
row 4 of i_txt = 'd'
row 5 of i_txt = 'e'
The only problem is that the BDC doesn't go thru on its own.  When I change 'N' to 'E', the BDC brings up a screen with the title:
"Change order text header Alternative Language EN"
Then, when I just "back-arrow" from this, the BDC does complete successfully and I can see the correct text saved for the order in IW32.
What am I doing wrong to cause this "change order text header" screen to come up?  Is it the "LTXK" value of the OK-CODE in the first dynpro call above?
Or maybe something with my default user parameters?  I had to set quite a few of these in order to get the BDC to go with just a system, priority, and short text/long text.
I'm really hoping you can see what's going on here because I'm at a loss.
Thanks for whatever help you can provide.  You seem to have coded this BDC before, so that's why I'm directing this question to you.
BTW, I'd try the BAPI except the documentation specifically says it won't observe user default parameters and this is a must in our situation.
Thanks again
Dave

Answer 1

Chris/Rich -
My suspicion was correct.  In the last loop over the longtext itab, the ok_code must be 'TXBA', not 'ENTR'.
Here's the code that works without any 'E' interruptions:
PERFORM DYNPRO USING:
'X' 'SAPLCOIH'          '3000',            "
' ' 'CAUFVD-KTEXT   '   SCRN_PROBLEM1,     " 1st line problem text
' ' 'CAUFVD-ANLZU   '   CAUFVD-ANLZU,      " System condition
' ' 'BDC_OKCODE'       '=LTXK'.            "
DESCRIBE TABLE i_txt LINES v_txt_cnt.
LOOP AT i_txt INTO wa_txt.
  v_txtln_ctr_n = sy-tabix + 2.
  v_txtln_ctr_c = v_txtln_ctr_n.
  CONCATENATE 'RSTXT-TXLINE('
              v_txtln_ctr_c
         INTO v_bdc_txtln_lit.
  CONDENSE v_bdc_txtln_lit NO-GAPS.
  IF sy-tabix = v_txt_cnt.
    v_txt_ok = '=TXBA'.                    " no more text lines coming
  ELSE.
    v_txt_ok = '=ENTR'.                    " more text lines coming
  ENDIF.
  PERFORM DYNPRO USING:
    'X' 'SAPLSTXX'          '1100',       
    ' ' v_bdc_txtln_lit     wa_txt,        " line of problem text
    ' ' 'BDC_OKCODE'        v_txt_ok.      " ok_code
ENDLOOP.
The result is that the longtest display in IW32 will be what's in "SCRN_PROBLEM1" followed by all the lines that are in i_txt.
Reagrds
djh