Formatted Search screen - populate multiple fields

Question

I have an Employee Id field in my screen.
On clicking Choose button,I use a Formatted Search screen to populate value to that field.
I also have other fields like employee Name,department which should be populated, once an employee Id is chosen from Formatted Search screen.
The functionality is like that of "Purchase Order screen".
Once a vendor Id is chosen Name,Contact Person etc get populated in "Purchase Order screen".
How do I do that?
Should I trap the Choose button event of Formatted Search screen?
Please help.

Answer 1

I think all you are missing is a check to make sure you don't try and re-run the lookup when you are validating the return value from a previous lookup.
I made a minor change to my code and achieved the behaviour you described.  I have extracted the relevant  code from the application .  Unfortunately it looses its indentation when I post it, so it might be quite hard to read.  It uses recordsets for the validation as in practice most of the real validation is more complex than this cut-down sample.
This particular example is from a screen with a Customer Code prompt, and displays the customers name below it.
Regards,
John.
<b>Constant holding menu uid of Formatted Search</b>
Public Const AZU_MNU_SEARCH             As Long = 7425
<b>Declare a variable at module level</b>
Dim mblnCardLookup as Boolean
<b>Create validation routine (cut down sample included)</b>
Sub ValidateCustomer(sboApp As SAPbouiCOM.Application, sboCompany As SAbobsCOM.Company, BubbleEvent As Boolean)
    On Error GoTo ErrorHandler
    Const AZU_PROCEDURENAME     As String = "ValidateCustomer"
    Dim sboRecordset            As SAPbobsCOM.Recordset
    Dim sboForm                 As SAPbouiCOM.Form
    Dim sboDSCard               As SAPbouiCOM.UserDataSource
    Dim sboDSName               As SAPbouiCOM.UserDataSource
    Set sboForm = sboApp.Forms(strUID)
    Set sboDSCard = sboForm.DataSources.UserDataSources("UCARD")
    Set sboDSName = sboForm.DataSources.UserDataSources("UNAME")
    If sboDSCard.value <> "" Then
        Set sboRecordset = sboCompany.GetBusinessObject(BoRecordset)
        sboRecordset.DoQuery "Select CardCode, CardName, Currency From OCRD where CardCode Like '" & sboDSCard.value & "%'"
        If sboRecordset.RecordCount < 1 Then
            If sboDSName.value <> "" Then
                sboDSName.value = ""
                sboForm.Items("edtName").Update
            End If
            If Not mblnCardLookup Then
                LookupCustomer sboApp
            End If
            BubbleEvent = False
            Exit Sub
        End If
        sboRecordset.MoveFirst
        sboDSCard.value = sboRecordset.Fields(0).value
        sboDSName.value = sboRecordset.Fields(1).value
        mstrCurrency = sboRecordset.Fields(2).value
        sboForm.Items("edtName").Update
    Else
        sboDSName.value = ""
        sboForm.Items("edtName").Update
        BubbleEvent = False
    End If
    Set sboDSName = Nothing
    Set sboDSCard = Nothing
    Set sboForm = Nothing
    Set sboRecordset = Nothing
    Exit Sub
ErrorHandler:
    Call AZU_STD_ERROR_MSGBOX(AZU_MODULENAME, AZU_PROCEDURENAME)
End Sub
<b>Create lookup routine (cut down sample included)</b>
Private Sub LookupCustomer(sboApp As SAPbouiCOM.Application)
    On Error GoTo ErrorHandler
    Const AZU_PROCEDURENAME     As String = "LookupCustomer"
    Dim sboForm                 As SAPbouiCOM.Form
    Set sboForm = sboApp.Forms(strUID)
    mblnCardLookup = True
    sboApp.ActivateMenuItem AZU_MNU_SEARCH
    Set sboForm = Nothing
    Exit Sub
ErrorHandler:
    Call AZU_STD_ERROR_MSGBOX(AZU_MODULENAME, AZU_PROCEDURENAME)
End Sub
<b>Add the following code to the ITEMEVENT handler</b>
    'Validate Customer Code
    If pVal.EventType = et_VALIDATE And pVal.ItemUID = "edtCard" And pVal.Before_Action = False Then
        Call ValidateCustomer(sboApp, sboCompany, BubbleEvent)
    End If
    'Customer Code Lookup on TAB Key
    If pVal.EventType = et_KEY_DOWN And pVal.ItemUID = "edtCard" And pVal.Before_Action = True And pVal.CharPressed = 9 Then
        Set sboDSCard = sboApp.Forms(strUID).DataSources.UserDataSources("UCARD")
        If sboDSCard.value = "" Then
            LookupCustomer sboApp
            BubbleEvent = False
        End If
    End If
    'Force Validation on Return from Lookup
    If pVal.EventType = et_FORM_ACTIVATE And mblnCardLookup = True Then
        sboApp.Forms(strUID).Items("edtRef").Click
        mblnCardLookup = False
    End If