Help! Export iTunes Playlist to Folder with Play Order

Question

Hello all,
I run a community internet radio station, and to upload songs to the server, a .zip file has to be uploaded. However, when a playlist, or a bunch of songs in a set is carried over, Finder reorganizes the files alphabetically, and it doesn't preserve song and play order which is essential. So, I did a few searches and there seemed to be a solution at macosxtips.com, this is the link: http://www.macosxhints.com/article.php?story=20080424194133862.
Basically, what it said was: start an automator workflow, and get selected itunes items, then copy finder items, and finally, rename files (sequentially). However, when I do this, the workflow seems to process endlessly without any results. It doesn't prompt me to add the files to a folder, and seems to get stuck at step one.
When I checked the log in Automator, it said, in regards to Get Selected iTunes Items, "The action 'Get Selected iTunes Items' was not supplied with the required data."
I've tried this both on my 24" aluminum iMac and my 15" new aluminum Macbook Pro with the same results.
I'm stuck, and I need to provide my team with a solution to upload their playlists. Any suggestoins? Thanks in advance, all of us here at www.itntradio.com appreciate your help.
See screenshot below -

Answer 1

OK, since you are desperate and all...
An AppleScript can easily do the same thing, so give this one a try. The following script works the same as your example workflow - it copies the selected iTunes items into the specified folder, renaming them by adding a prefix (I used your workflow example for the details):
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFEE80;
overflow: auto;"
title="this text can be pasted into the Script Editor">
(* copy and rename iTunes items *)
if application "iTunes" is not running then
display alert "iTunes is not running" message "Please activate iTunes and select items."
return
end if
-- set up a few things
choose folder with prompt "Choose a folder to copy the selected iTunes items into:" default location (path to desktop)
set DestinationFolder to the result
set {PrefixNumber, TrackLocations} to {0, {}}
-- get filepaths of the selected iTunes items
tell application "iTunes" to repeat with SomeTrack in (get the selection)
try -- skip items that are not file tracks (no location)
set the end of TrackLocations to location of SomeTrack
end try
end repeat
-- copy and rename
repeat with SomeFile in TrackLocations
set PrefixNumber to text 2 thru -1 of ((1000 + PrefixNumber + 1) as text) -- prefix with leading zeros
tell application "Finder"
set NewName to PrefixNumber & "-" & (get name of SomeFile)
set the name of (duplicate SomeFile to DestinationFolder) to NewName
end tell
end repeat
tell application "Finder" to reveal DestinationFolder
</pre>