Help on DML Triggers On Schema

Question

All,
We are in the process of implementing audit table for specific schemas:(user1 120 tables)
I was successfully able to create DDL Triggers on the Schema with ----- DDL ON SCHEMA
but for tracking DML operations on each table by different users in user1 schema... do i need to create individual trigger for each table...
BEFORE INSERT OR UPDATE OR DELETE ON <TABLE_NAME>
is this the only way...
Any Ideas?
Regards,
~Ora

Answer 1

Hi,
as you said in your first post, for DDL operations you can use SCHEMA a level trigger, but for DLM operations you will have to stick with one trigger per Table.
Here is some piece of code to generate the triggers for you.
drop type line_tt;
create or replace type line_t as object (x varchar2(4000));
create or replace type line_tt as table of line_t;
create or replace function generate_audit_triggers return line_tt pipelined
is
       cursor my_tables is
              select user as owner, table_name from user_tables where temporary = 'N';
       cursor my_table_cols(tablename in varchar2) is
              select column_name from user_tab_columns where table_name = tablename order by column_name;
       sqlstatement varchar2(4000);      
       wherestatement varchar2(4000);
begin
     for r_table in my_tables loop
         -- generate code for insert trigger
         pipe row(line_t('create or replace trigger ' || r_table.owner || '.' || substr('SPYI_' || r_table.table_name, 1, 30)));
         pipe row(line_t('before insert on ' || r_table.owner || '.' || r_table.table_name));
         pipe row(line_t('for each row'));
         pipe row(line_t('begin'));
         pipe row(line_t('insert into AUDIT_DATA(sqlstatement) values('));
         sqlstatement := '''insert into ' || r_table.owner || '.' || r_table.table_name || '(';
         for r_column in my_table_cols(r_table.table_name) loop
             sqlstatement := sqlstatement || r_column.column_name;
             sqlstatement := sqlstatement || ',';
         end loop;
         sqlstatement := substr(sqlstatement, 1, length(sqlstatement) - 1);
         sqlstatement := sqlstatement || ') values ('''''' || ';
         for r_column in my_table_cols(r_table.table_name) loop
             sqlstatement := sqlstatement || ':new.' || r_column.column_name;
             sqlstatement := sqlstatement || ' || '''''','''''' || ';
         end loop;
         sqlstatement := substr(sqlstatement, 1, length(sqlstatement) - 10);
         sqlstatement := sqlstatement || ''''');''';
         pipe row(line_t(sqlstatement));
         pipe row(line_t(');'));
         pipe row(line_t('end;'));
         pipe row(line_t('/'));
         -- generate code for update trigger
         pipe row(line_t('create or replace trigger ' || r_table.owner || '.' || substr('SPYU_' || r_table.table_name, 1, 30)));
         pipe row(line_t('before update on ' || r_table.owner || '.' || r_table.table_name));
         pipe row(line_t('for each row'));
         pipe row(line_t('begin'));
         sqlstatement := 'if (';
         for r_column in my_table_cols(r_table.table_name) loop
             sqlstatement := sqlstatement || '''a''|| ' || ':old.' || r_column.column_name || ' <> ''a''|| :new.' || r_column.column_name || ' or ';
         end loop;
         sqlstatement := substr(sqlstatement, 1, length(sqlstatement) - 4);
         sqlstatement := sqlstatement || ') then';
         pipe row(line_t(sqlstatement));
         pipe row(line_t('insert into AUDIT_DATA(sqlstatement) values('));
         sqlstatement := '''update ' || r_table.owner || '.' || r_table.table_name || ' set ';           
         wherestatement := ' where ';
         for r_column in my_table_cols(r_table.table_name) loop
             sqlstatement := sqlstatement || r_column.column_name || '=''''' || ''' || :new.' || r_column.column_name || ' || '''''',';
             wherestatement := wherestatement || '''''a''''||' || r_column.column_name || '=''''a''''||''''' || ''' || :old.' || r_column.column_name || ' || '''''' and ';
         end loop;
         sqlstatement := substr(sqlstatement, 1, length(sqlstatement) - 1);
         wherestatement := substr(wherestatement, 1, length(wherestatement) - 5);
         sqlstatement := sqlstatement || wherestatement || ';''';
         pipe row(line_t(sqlstatement));
         pipe row(line_t(');'));
         pipe row(line_t('end if;'));
         pipe row(line_t('end;'));
         pipe row(line_t('/'));
     end loop;
end;
show err
drop table audit_data;
create table audit_data (
       sqlstatement varchar2(4000)
spool tmp.sql
set head off
set linesize 500
set echo off
select x from table(generate_audit_triggers);
spool offHope this helps,
Francois