Help to create simple Applescript

Question

Hi, hopefully somebody will be able to help me with a simple Applescript.
I want to be able to drag a pdf file onto a desktop icon, enter a new filename into a dialogue box and for the file to be copied to a specific folder. It will only be pdf files, and I want it to automatically append the .pdf extension.
Could sombody possibly point me in the right direction? Thanks in advance.

Answer 1

Oops, forgot one more check. If a file exists with the same name as the original file, then it will error when you duplicate it. One way to solve that is to duplicate in place. Then "copy" is added to the name. You then move the file to the destination folder and probably there is no file with "copy" in its name.
property folder_location : (path to desktop)
property folder_name : "Files"
on open these_items
-- added check for main folder
tell application "Finder"
try
set main_folder to (folder folder_name of folder_location) as alias
on error
set main_folder to (make new folder at folder_location with properties ¬
{name:folder_name})
end try
end tell
repeat with this_item in these_items
set n to name of (info for this_item)
if n ends with ".pdf" then
set temp_prompt to "Enter a name for duplicate of " & n & ":"
repeat
display dialog temp_prompt default answer "name"
set new_name to (text returned of result) & ".pdf"
tell application "Finder"
if not (exists file new_name of main_folder) then
set the_duplicate to (duplicate this_item) as alias
move the_duplicate to main_folder
set name of the_duplicate to new_name
exit repeat
else -- inform user to enter a different name
set temp_prompt to "Enter a different name. The name " & new_name & " is used."
end if
end tell
end repeat
end if
end repeat
end open
Otherwise, What I usually do is create a empty temp folder for doing renaming, but then it gets more complicated. For now, just don't use "copy" in names.
gl,