How to calculate the percentage of free space for a table in Oracle

Question

okay, I am a little confused here. I have been searching the web and looking at a lot of documents. What I basically want to find out is this, how do I calculate the difference between the number of bytes a table is using and the total bytes allocated to a table space (going that way to get percent free for a particular table). So I need a byte count of a table and total table space and the percentage difference. I have been looking at the DBA_TABLES DBA_TABLESPACES and DBA_SEGMENTS views. I have tried to calculated the space as num_rows * avg_row_len (if I am wrong, let me know). I have been trying to compare that calculation to the number in DBA_TABLESPACES and DBA_SEGMENTS. I am just looking for the total space allocated to the table space that the table sits in (seem logical right now) to make the percentage value work. Thus I want to be able to track the table as it grows as compated to the table space it sits in to see a value as it changes over time (days, weeks, etc.) each time I run this script I am working on.
Can someone get me straight and help me to find out if I am looking in the right places. Any advice would help.
Edward

Answer 1

You can use a little modified version of dbms_space from Tom, show_space. Have a look,
SQL> create table test222 as select * from all_objects;
Table created.
SQL> delete from test22 where rownum<=100;
delete from test22 where rownum<=100
ERROR at line 1:
ORA-00942: table or view does not exist
SQL> delete from test222 where rownum<=100;
100 rows deleted.
SQL> analyze table test222 compute statistics;
Table analyzed.
SQL>  create or replace procedure show_space
  2  ( p_segname in varchar2,
  3    p_owner   in varchar2 default user,
  4    p_type    in varchar2 default 'TABLE',
  5    p_partition in varchar2 default NULL )
  6  -- this procedure uses authid current user so it can query DBA_*
  7  -- views using privileges from a ROLE and so it can be installed
  8  -- once per database, instead of once per user that wanted to use it
  9  authid current_user
10  as
11      l_free_blks                 number;
12      l_total_blocks              number;
13      l_total_bytes               number;
14      l_unused_blocks             number;
15      l_unused_bytes              number;
16      l_LastUsedExtFileId         number;
17      l_LastUsedExtBlockId        number;
18      l_LAST_USED_BLOCK           number;
19      l_segment_space_mgmt        varchar2(255);
20      l_unformatted_blocks number;
21      l_unformatted_bytes number;
22      l_fs1_blocks number; l_fs1_bytes number;
23      l_fs2_blocks number; l_fs2_bytes number;
24      l_fs3_blocks number; l_fs3_bytes number;
25      l_fs4_blocks number; l_fs4_bytes number;
26      l_full_blocks number; l_full_bytes number;
27
28      -- inline procedure to print out numbers nicely formatted
29      -- with a simple label
30      procedure p( p_label in varchar2, p_num in number )
31      is
32      begin
33          dbms_output.put_line( rpad(p_label,40,'.') ||
34                                to_char(p_num,'999,999,999,999') );
35      end;
36  begin
37     -- this query is executed dynamically in order to allow this procedure
38     -- to be created by a user who has access to DBA_SEGMENTS/TABLESPACES
39     -- via a role as is customary.
40     -- NOTE: at runtime, the invoker MUST have access to these two
41     -- views!
42     -- this query determines if the object is a ASSM object or not
43     begin
44        execute immediate
45            'select ts.segment_space_management
46               from dba_segments seg, dba_tablespaces ts
47              where seg.segment_name      = :p_segname
48                and (:p_partition is null or
49                    seg.partition_name = :p_partition)
50                and seg.owner = :p_owner
51                and seg.tablespace_name = ts.tablespace_name'
52               into l_segment_space_mgmt
53              using p_segname, p_partition, p_partition, p_owner;
54     exception
55         when too_many_rows then
56            dbms_output.put_line
57            ( 'This must be a partitioned table, use p_partition => ');
58            return;
59     end;
60
61
62     -- if the object is in an ASSM tablespace, we must use this API
63     -- call to get space information, else we use the FREE_BLOCKS
64     -- API for the user managed segments
65     if l_segment_space_mgmt = 'AUTO'
66     then
67       dbms_space.space_usage
68       ( p_owner, p_segname, p_type, l_unformatted_blocks,
69         l_unformatted_bytes, l_fs1_blocks, l_fs1_bytes,
70         l_fs2_blocks, l_fs2_bytes, l_fs3_blocks, l_fs3_bytes,
71         l_fs4_blocks, l_fs4_bytes, l_full_blocks, l_full_bytes, p_partition);
72
73       p( 'Unformatted Blocks ', l_unformatted_blocks );
74       p( 'FS1 Blocks (0-25)  ', l_fs1_blocks );
75       p( 'FS2 Blocks (25-50) ', l_fs2_blocks );
76       p( 'FS3 Blocks (50-75) ', l_fs3_blocks );
77       p( 'FS4 Blocks (75-100)', l_fs4_blocks );
78       p( 'Full Blocks        ', l_full_blocks );
79    else
80       dbms_space.free_blocks(
81         segment_owner     => p_owner,
82         segment_name      => p_segname,
83         segment_type      => p_type,
84         freelist_group_id => 0,
85         free_blks         => l_free_blks);
86
87       p( 'Free Blocks', l_free_blks );
88    end if;
89
90    -- and then the unused space API call to get the rest of the
91    -- information
92    dbms_space.unused_space
93    ( segment_owner     => p_owner,
94      segment_name      => p_segname,
95      segment_type      => p_type,
96      partition_name    => p_partition,
97      total_blocks      => l_total_blocks,
98      total_bytes       => l_total_bytes,
99      unused_blocks     => l_unused_blocks,
100      unused_bytes      => l_unused_bytes,
101      LAST_USED_EXTENT_FILE_ID => l_LastUsedExtFileId,
102      LAST_USED_EXTENT_BLOCK_ID => l_LastUsedExtBlockId,
103      LAST_USED_BLOCK => l_LAST_USED_BLOCK );
104
105      p( 'Total Blocks', l_total_blocks );
106      p( 'Total Bytes', l_total_bytes );
107      p( 'Total MBytes', trunc(l_total_bytes/1024/1024) );
108      p( 'Unused Blocks', l_unused_blocks );
109      p( 'Unused Bytes', l_unused_bytes );
110      p( 'Last Used Ext FileId', l_LastUsedExtFileId );
111      p( 'Last Used Ext BlockId', l_LastUsedExtBlockId );
112      p( 'Last Used Block', l_LAST_USED_BLOCK );
113  end;
114
115  /
Procedure created.
SQL> desc show_space
PROCEDURE show_space
Argument Name                  Type                    In/Out Default?
P_SEGNAME                      VARCHAR2                IN
P_OWNER                        VARCHAR2                IN     DEFAULT
P_TYPE                         VARCHAR2                IN     DEFAULT
P_PARTITION                    VARCHAR2                IN     DEFAULT
SQL> set serveroutput on
SQL> exec show_space('TEST222','SCOTT');
BEGIN show_space('TEST222','SCOTT'); END;
ERROR at line 1:
ORA-00942: table or view does not exist
ORA-06512: at "SCOTT.SHOW_SPACE", line 44
ORA-06512: at line 1
SQL> conn / as sysdba
Connected.
SQL> grant sysdba to scott;
Grant succeeded.
SQL> conn scott/tiger as sysdba
Connected.
SQL> exec show_space('TEST222','SCOTT');
BEGIN show_space('TEST222','SCOTT'); END;
ERROR at line 1:
ORA-06550: line 1, column 7:
PLS-00201: identifier 'SHOW_SPACE' must be declared
ORA-06550: line 1, column 7:
PL/SQL: Statement ignored
SQL> exec scott.show_space('TEST222','SCOTT');
PL/SQL procedure successfully completed.
SQL> set serveroutput on
SQL> exec scott.show_space('TEST222','SCOTT');
Unformatted Blocks .....................               0
FS1 Blocks (0-25)  .....................               0
FS2 Blocks (25-50) .....................               1
FS3 Blocks (50-75) .....................               0
FS4 Blocks (75-100).....................               1
Full Blocks        .....................             807
Total Blocks............................             896
Total Bytes.............................       7,340,032
Total MBytes............................               7
Unused Blocks...........................              65
Unused Bytes............................         532,480
Last Used Ext FileId....................               4
Last Used Ext BlockId...................           1,289
Last Used Block.........................              63
PL/SQL procedure successfully completed.
SQL>http://asktom.oracle.com/pls/asktom/f?p=100:11:0::::P11_QUESTION_ID:5350053031470
I use this to find the space allocations.
Just read your post again,this is not going to show you the percentage of the free/used space. This is going to be the number of blocks which are free/used. For the growth trend, you can look at (in 10g) Oracle EM. It has added now,Segment Growth Trend report which can show you for each object,comparing to the allocated space to the object,how much space is being used by it.
HTH
Aman....