How to create POV help

Question

Hi all,
Please tell me how to create POV help for module pool.
Regards,

Answer 1

hi,
Try this
PROCESS ON VALUE-REQUEST.
* Module to fetch the branch value
* from the screen
  FIELD zval_discount-zbranch
  MODULE value_branch.
* field Discount type WRT Branch
  FIELD zval_discount-zdisctyp
  MODULE f4_help_discount_type .
MODULE value_branch INPUT.
  CALL FUNCTION 'F4IF_FIELD_VALUE_REQUEST'
    EXPORTING
      tabname           = 'ZVAL_DISCOUNT'
      fieldname         = 'ZBRANCH'
      dynpprog          = sy-repid
      dynpnr            = sy-dynnr
      dynprofield       = 'ZBRANCH'
    EXCEPTIONS
      field_not_found   = 1
      no_help_for_field = 2
      inconsistent_help = 3
      no_values_found   = 4
      OTHERS            = 5.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDMODULE.                 " value_branch  INPUT
MODULE f4_help_discount_type INPUT.
  REFRESH :
    i_dynpread,
    r_branch,
    i_disctyp.
  CLEAR   wa_dynpread.
  IF sy-dynnr = '0120'.
    wa_dynpread-fieldname = 'ZVAL_DISCOUNT-ZBRANCH'.
    APPEND wa_dynpread TO i_dynpread .
* Function module to read the value of ZBRANCH on the screen 120.
    CALL FUNCTION 'DYNP_VALUES_READ'
      EXPORTING
        dyname               = sy-repid
        dynumb               = sy-dynnr
        translate_to_upper   = 'X'
      TABLES
        dynpfields           = i_dynpread
      EXCEPTIONS
        invalid_abapworkarea = 1
        invalid_dynprofield  = 2
        invalid_dynproname   = 3
        invalid_dynpronummer = 4
        invalid_request      = 5
        no_fielddescription  = 6
        invalid_parameter    = 7
        undefind_error       = 8
        double_conversion    = 9
        stepl_not_found      = 10
        OTHERS               = 11.
    IF sy-subrc EQ 0.
      READ TABLE i_dynpread INDEX 1 INTO wa_dynpread.
      IF sy-subrc EQ 0.
        MOVE wa_dynpread-fieldvalue TO zval_discount-zbranch.
      ENDIF.
    ELSE.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
  ELSE.
    CLEAR v_stepl.
    CALL FUNCTION 'DYNP_GET_STEPL'
      IMPORTING
        povstepl        = v_stepl
      EXCEPTIONS
        stepl_not_found = 1
        OTHERS          = 2.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
    READ TABLE g_val_disc_maint_itab INTO g_val_disc_maint_wa
    INDEX v_stepl.
    IF sy-subrc EQ 0.
      zval_discount-zbranch = g_val_disc_maint_wa-zbranch.
    ENDIF.
  ENDIF.
  IF NOT zval_discount-zbranch IS INITIAL.
    r_branch-sign = 'I'.
    r_branch-option = 'EQ'.
    r_branch-low = zval_discount-zbranch.
    APPEND r_branch.
  ENDIF.
* Fetch the recods of purchase type for the
*  branch selected on the screen
  SELECT *
    FROM zval_disctyp
    INTO TABLE i_disctyp
   WHERE zbranch IN r_branch.
* Function module for F4 help for the field Purchase Type
  CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
    EXPORTING
      ddic_structure  = 'ZVAL_DISCTYP'
      retfield        = 'ZDISCTYP'
      dynpprog        = sy-repid
      dynpnr          = sy-dynnr
      dynprofield     = 'ZVAL_DISCOUNT-ZDISCTYP'
      window_title    = 'Discount Type'(016)
      value_org       = 'S'
    TABLES
      value_tab       = i_disctyp
      return_tab      = i_ddshretval
    EXCEPTIONS
      parameter_error = 1
      no_values_found = 2
      OTHERS          = 3.
  IF sy-subrc EQ 0.
    READ TABLE i_ddshretval INDEX 1.
    IF sy-subrc EQ 0.
      MOVE i_ddshretval-fieldval TO zval_discount-zdisctyp.
    ENDIF.
  ELSE.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDMODULE.                 " f4_help_discount_type  INPUT
Edited by: avinash kodarapu on Jan 5, 2009 12:34 PM