How to get latest added file from a folder using apple script

Question

Hi..
I am trying to get a latest added file from a folder..and for this i have below script
tell application "Finder"
    set latestFile to item 1 of (sort (get files of (path to downloads folder)) by creation date) as alias
    set fileName to latestFile's name
end tell
By using this i am not able to get latest file because for some files the creation date is some older date so is there any way to get latest file based on "Date Added" column of a folder.

Answer 1

If you don't mind using GUI Scripting (you must enable access for assistive devices in the Accessibility System Preference pane), the following script should give you a reference to the last item added to any folder. Admittedly not the most elegant solution, but it works, at least under OS X 10.8.2.
set theFolder to choose folder
tell application "Finder"
    activate
    set theFolderWindow to container window of theFolder
    set alreadyOpen to exists theFolderWindow
    tell theFolderWindow
        open
        set theInitialView to current view
        set current view to icon view
    end tell
end tell
tell application "System Events" to tell process "Finder"
    -- Arrange by None:
    set theInitialArrangement to name of menu item 1 of menu 1 of menu item "Arrange By" of menu 1 of menu bar item "View" of menu bar 1 whose value of attribute "AXMenuItemMarkChar" is "✓"
    keystroke "0" using {control down, command down}
    -- Sort by Date Added:
    set theInitialSortingOrder to name of menu item 1 of menu 1 of menu item "Sort By" of menu 1 of menu bar item "View" of menu bar 1 whose value of attribute "AXMenuItemMarkChar" is "✓"
    keystroke "4" using {control down, option down, command down}
    -- Get the name of the last item:
    set theItemName to name of image 1 of UI element 1 of last scroll area of splitter group 1 of (window 1 whose subrole is "AXStandardWindow")
    -- Restore the initial settings:
    click menu item theInitialSortingOrder of menu 1 of menu item "Sort By" of menu 1 of menu bar item "View" of menu bar 1
    click menu item theInitialArrangement of menu 1 of menu item "Arrange By" of menu 1 of menu bar item "View" of menu bar 1
end tell
tell application "Finder"
    set current view of theFolderWindow to theInitialView -- restore the initial view
    if not alreadyOpen then close theFolderWindow
    set theLastItem to item theItemName of theFolder
end tell
theLastItem
Message was edited by: Pierre L.