How to have backend account determination working SRM

Question

Hello everybody
Just came across thread
EBP G/L Account Assignment doesn't  follow R/3 Account Determination
while I was searching for a solution to this same problem I'm having here as well. I already thought about using BAdI BBP_DETERMINE_ACCT. But I'm stuck to find the right backend function module (R/3 4.7) in order to ask for the G/L account coming from the backend account determination.
Did somebody already solve this and if yes is willing to share knowledge?
Any useful help will of course be rewarded with points!
Best regards,
Renaud

Answer 1

<b>The function module in R/3 backend systems looks like that:</b>
FUNCTION <your function module name here>.
*"*"Lokale Schnittstelle:
*"  IMPORTING
*"     VALUE(I_MATNR) TYPE  MARA-MATNR
*"     VALUE(I_BUKRS) LIKE  T001-BUKRS
*"  EXPORTING
*"     VALUE(E_KONTO) LIKE  T030-KONTH
*"     VALUE(E_BSCHH) LIKE  T030B-BSCHH
*"  EXCEPTIONS
*"      NOT_FOUND
  DATA: w_subrc LIKE sy-subrc.
  DATA: i_ktopl LIKE t001-ktopl.
  DATA: i_bklas LIKE mbew-bklas.
  CLEAR: w_subrc, i_ktopl, i_bklas, e_bschh, e_konto.
* Determine chart of accounts
  SELECT SINGLE ktopl FROM t001 INTO i_ktopl
    WHERE bukrs = i_bukrs.
  w_subrc = w_subrc + sy-subrc.
* Determine bklas from material
  SELECT SINGLE bklas FROM mbew INTO i_bklas
    WHERE matnr = i_matnr
    AND   bwkey = '1000'
    AND   bwtar = space.
  w_subrc = w_subrc + sy-subrc.
* Determine G/L account
  CALL FUNCTION 'MR_ACCOUNT_ASSIGNMENT'
    EXPORTING
      bewertungsklasse       = i_bklas
      bewertung_modif        = '1000'
      kontenplan             = i_ktopl
      konto_modif            = 'VBR'
      soll_haben_kennzeichen = 'S'
      vorgangsschluessel     = 'GBB'
    IMPORTING
      buchungsschluessel     = e_bschh
      konto                  = e_konto
    EXCEPTIONS
      NOT_FOUND_T030         = 1
      NOT_FOUND_T030B        = 2
      NOT_FOUND_T030R        = 3
      NOT_FOUND_T030S        = 4
  w_subrc = w_subrc + sy-subrc.
  IF w_subrc <> 0.
    MESSAGE i100(zpcg_mm) WITH i_matnr RAISING not_found.
  ENDIF.
ENDFUNCTION.
<b>The BAdI code in SRM looks like that:</b>
method IF_EX_BBP_DETERMINE_ACCT~DETERMINE_ACCOUNT.
  data: e_konto(10) TYPE C,
        e_bschh(2)  TYPE C,
        wa_acct_data TYPE BBP_OCI_ENRACCT.
  IF NOT item_data-ordered_prod IS INITIAL.
    CALL FUNCTION '<your function module name here>'
      DESTINATION item_data-product_src_sys
      EXPORTING
        i_matnr = item_data-ordered_prod
        i_bukrs = item_data-co_code
      IMPORTING
        e_konto = e_konto
        e_bschh = e_bschh
      EXCEPTIONS
        NOT_FOUND = 1
    IF sy-subrc = 0.
      LOOP AT acct_data INTO wa_acct_data
        WHERE line = item_data-line.
        wa_acct_data-g_l_acct = e_konto.
        MODIFY acct_data FROM wa_acct_data.
      ENDLOOP.
    ENDIF.
  ENDIF.
endmethod.
<b></b>