How to send attachment mail in sap

Question

hi all,
please guide me how to use function module named SO_NEW_DOCUMENT_ATT_SEND_API1.
i have text files in internal table.
please guide me how can i send files in my internal table as in attachment.

Answer 1

Manish,
Just copy paste the below code as given into a report only changing the email address of receipient to your email address to testing.
That is line:
lwa_reclist-receiver = '[email protected]'. " Email address of your receipient
Then I think your SCOT is not configured for automatic execution hence once you have run your report go to transaction SCOT and press (Ctrl + F7) to start send process.
A mail will be sent to your email address specified in the receipient list and a copy of it also placed in your SBWP Outbox.
Let me know if you need further help, else reward neccessary points.
Code
*& Report  ZMFV_ROUGH_PAD
REPORT  zmfv_rough_pad.
DATA :
li_attachment TYPE TABLE OF soli, " hold attachment contents
li_pdf        TYPE TABLE OF tline, " hold data from spool in PDF format
li_objpack    TYPE TABLE OF sopcklsti1, " hold email body, attachment details
li_objtxt     TYPE TABLE OF solisti1, " hold message contents
li_reclist    TYPE TABLE OF somlreci1. " hold email reciever details
DATA :
lwa_attachment    LIKE LINE OF li_attachment,
lwa_pdf           LIKE LINE OF li_pdf,
lwa_objpack       LIKE LINE OF li_objpack,
lwa_objtxt        LIKE LINE OF li_objtxt,
lwa_reclist       LIKE LINE OF li_reclist,
lwa_document_data TYPE sodocchgi1. " hold document details like title, size etc.
DATA :
lv_sent_to_all     TYPE c, " flag to check if mail is sent to all
l_att_lines        TYPE i, " hold number of lines in attachment table
lv_spool_desc(68)  TYPE c. " hold description of spool
CONSTANTS : lc_email_txt TYPE solisti1-line VALUE 'Find attached Payment Advice sent by this email.',
lc_sensitivity TYPE sodocchgi1-sensitivty VALUE 'O',
lc_raw         TYPE sopcklsti1-doc_type VALUE 'RAW',
lc_pdf         TYPE sopcklsti1-doc_type VALUE 'PDF',
lc_transf_bin  TYPE sopcklsti1-transf_bin VALUE 'X',
lc_email       TYPE sopcklsti1-obj_name VALUE 'Email',
lc_ext_id      TYPE somlreci1-rec_type VALUE 'U',
lc_outbox      TYPE sonv-flag VALUE 'X',
lc_obj_name    TYPE sodocchgi1-obj_name VALUE 'Email Test',
lc_1           TYPE n VALUE '1',
lc_0           TYPE n VALUE '0'.
CLEAR: lwa_attachment,
lwa_pdf,
lwa_reclist,
lwa_objtxt,
lwa_objpack,
lwa_document_data.
REFRESH : li_attachment,
li_pdf,
li_reclist,
li_objtxt,
li_objpack.
Build attachment table
lwa_attachment-line = 'YOUR TEXT FROM INTERNAL TABLE LINES'.
APPEND lwa_attachment TO li_attachment.
Body of email
CLEAR lwa_objtxt.
MOVE lc_email_txt TO lwa_objtxt.
APPEND lwa_objtxt TO li_objtxt.
Title of the email
lwa_document_data-obj_descr = 'Title of email'.
lwa_document_data-sensitivty = lc_sensitivity.
lwa_document_data-expiry_dat = sy-datum + 15.
lwa_document_data-doc_size = STRLEN( lwa_objtxt ).
lwa_document_data-obj_name = lc_obj_name.
e-mail body
CLEAR lwa_objpack.
lwa_objpack-head_start = lc_1.
lwa_objpack-head_num = lc_0.
lwa_objpack-body_start = lc_1.
lwa_objpack-body_num = lc_1.
lwa_objpack-doc_type = lc_raw.
lwa_objpack-doc_size = STRLEN( lwa_objtxt ).
APPEND lwa_objpack TO li_objpack.
For e-mail attachment
DESCRIBE TABLE li_attachment LINES l_att_lines.
CLEAR lwa_attachment.
READ TABLE li_attachment INDEX l_att_lines INTO lwa_attachment.
CLEAR lwa_objpack.
lwa_objpack-transf_bin = lc_transf_bin.
lwa_objpack-head_start = lc_1.
lwa_objpack-head_num = lc_1.
lwa_objpack-body_start = lc_1.
lwa_objpack-body_num = l_att_lines.
lwa_objpack-doc_type = lc_raw.
lwa_objpack-obj_name = lc_email.
lwa_objpack-obj_descr = lv_spool_desc.
lwa_objpack-doc_size = ( 255 * ( l_att_lines - 1 ) ) + STRLEN( lwa_attachment-line ).
APPEND lwa_objpack TO li_objpack.
make recipient list
CLEAR lwa_reclist.
lwa_reclist-receiver = '[email protected]'. " Email address of your receipient
lwa_reclist-rec_type = lc_ext_id. " To external email id
lwa_reclist-COM_TYPE = 'INT'.     " Internet mail
APPEND lwa_reclist TO li_reclist.
send mail with attachment
CALL FUNCTION 'SO_NEW_DOCUMENT_ATT_SEND_API1'
  EXPORTING
    document_data              = lwa_document_data
    put_in_outbox              = lc_outbox
    commit_work                = 'X'
  IMPORTING
    sent_to_all                = lv_sent_to_all
  TABLES
    packing_list               = li_objpack
    contents_bin               = li_attachment
    contents_txt               = li_objtxt
    receivers                  = li_reclist
  EXCEPTIONS
    too_many_receivers         = 1
    document_not_sent          = 2
    document_type_not_exist    = 3
    operation_no_authorization = 4
    parameter_error            = 5
    x_error                    = 6
    enqueue_error              = 7
    OTHERS                     = 8.
IF sy-subrc = 0.
  WRITE: 'Success'.
ENDIF.