How to use a balance dimension in a FastFormula

Question

Hello all,
How can I call a certain balance dimension and store it in a local variable like SALARY_ASG_RUN.
Regards,
Usher

Answer 1

Hi,
You cannot get a previous month's balance value from a DBI in the formula.
You need to write a formula function which gets you the data -
We have used the below for the same
-- GET_PREV_SALARY
FUNCTION get_prev_salary(p_assignment_action_id   IN NUMBER
                        ,p_balance_name           IN VARCHAR2
                        ,p_database_item_suffix   IN VARCHAR2
                        ,p_period_start_date      IN DATE
                        ,p_no_month               IN NUMBER
                        ,p_flag                   IN VARCHAR2
                        ,p_context                IN VARCHAR2
                        ,p_context_val            IN VARCHAR2
                        ,p_days                   IN OUT NOCOPY NUMBER) RETURN NUMBER
IS
    CURSOR get_prev_periods_dates (c_assignment_action_id NUMBER
                                  ,c_period_start_date    DATE) IS
    SELECT  ptp.start_date  start_date
           ,ptp.end_date    end_date
           ,ppa.action_type
           ,MAX(paa2.assignment_action_id) assignment_action_id
     FROM   pay_assignment_actions paa1
           ,pay_assignment_actions paa2
           ,per_all_assignments_f  paaf1
           ,per_all_assignments_f  paaf2
           ,pay_payroll_actions    ppa
           ,pay_payroll_actions    ppa1
           ,per_time_periods       ptp
           ,per_time_period_types  ptpt
     WHERE  paa1.assignment_action_id     = c_assignment_action_id
     AND    ppa1.payroll_action_id        = paa1.payroll_action_id
     AND    ppa1.business_group_id        = paaf1.business_group_id
     AND    paa1.assignment_id            = paaf1.assignment_id
     AND    paaf1.person_id               = paaf2.person_id
     AND    paaf2.business_group_id       = paaf1.business_group_id
     AND    paaf2.assignment_id           = paa2.assignment_id
--    AND    paa1.tax_unit_id              = paa2.tax_unit_id
     AND    paa2.payroll_action_id        = ppa.payroll_action_id
     AND    paa2.source_action_id         IS NULL
     AND    ptp.start_date                < c_period_start_date
     AND    ppa.payroll_id                = ptp.payroll_id
     AND    ppa.business_group_id          = paaf2.business_group_id
     AND    ptp.period_type                = ptpt.period_type
     AND    ppa.action_type               IN ('R','Q','I','B')
     AND    ppa.action_status             IN('C','U')
     AND    ppa.date_earned  BETWEEN ptp.start_date              AND ptp.end_date
     AND    ptp.end_date     BETWEEN paaf1.effective_start_date  AND paaf1.effective_end_date
     AND    ptp.end_date     BETWEEN paaf2.effective_start_date  AND paaf2.effective_end_date
     GROUP BY ptp.start_date, ptp.end_date, ppa.action_type
     ORDER BY 1 desc;
/*  SELECT ptp.start_date start_date
          ,ptp.end_date end_date
          ,ppa.action_type
          ,MAX(paa2.assignment_action_id) assignment_action_id
    FROM   pay_assignment_actions paa1
          ,pay_assignment_actions paa2
          ,per_all_assignments_f paaf1
          ,per_all_assignments_f paaf2
          ,pay_payroll_actions ppa
          ,per_time_periods ptp
    WHERE paa1.assignment_action_id     = c_assignment_action_id
    AND   paa1.assignment_id            = paaf1.assignment_id
    AND   paaf1.person_id               = paaf2.person_id
    AND   paaf2.assignment_id           = paa2.assignment_id
    AND   paa1.tax_unit_id              = paa2.tax_unit_id
    AND   paa2.payroll_action_id        = ppa.payroll_action_id
    AND   paa2.source_action_id         IS NULL
    AND   ptp.start_date < c_period_start_date
    AND   ppa.payroll_id                = ptp.payroll_id
    AND   ppa.time_period_id            = ptp.time_period_id
    AND   ppa.action_type IN ('R','Q','I','B')
    AND   ppa.action_status             IN('C','U')
    AND   ptp.end_date BETWEEN paaf1.effective_start_date
                                        AND paaf1.effective_end_date
    AND   ptp.end_date BETWEEN paaf2.effective_start_date
                                        AND paaf2.effective_end_date
    GROUP BY ptp.start_date, ptp.end_date, ppa.action_type
    ORDER BY 1 desc;
    CURSOR get_legal_employer_id(c_work_center_id NUMBER) IS
    SELECT  hoi.organization_id
    FROM    hr_organization_information hoi
    WHERE   hoi.org_information1         = c_work_center_id
    AND     hoi.org_information_context  = 'ES_WORK_CENTER_REF';
    l_def_bal_id          NUMBER;
    l_amount              NUMBER;
    l_amt                 NUMBER;
    l_ctr                 NUMBER;
    l_cnt                 NUMBER;
    l_start_date          DATE;
    l_date                DATE;
    l_legal_employer_id   hr_All_organization_units.organization_id%TYPE;
BEGIN
    hr_utility.trace('~~Entering pay_es_ss_calculation.get_prev_salary');
    l_def_bal_id := get_defined_bal_id(p_balance_name, p_database_item_suffix);
    hr_utility.trace('~~~~ p_balance_name'||p_balance_name);
    hr_utility.trace('~~~~ p_database_item_suffix'||p_database_item_suffix);
    hr_utility.trace('~~~~ l_def_bal_id'||l_def_bal_id);
    l_amount := 0;
    l_amt := 0;
    l_ctr := 0;
    l_cnt := 0;
    p_days := 0;
    l_date := to_date('01-01-0001','dd-mm-yyyy');
    IF p_context = 'TAX_UNIT_ID' THEN
        OPEN  get_legal_employer_id(to_number(p_context_val));
        FETCH get_legal_employer_id INTO l_legal_employer_id;
        CLOSE get_legal_employer_id;
        pay_balance_pkg.set_context('TAX_UNIT_ID', l_legal_employer_id);
        hr_utility.trace('~~~~ Setting TAX_UNIT_ID Context '||l_legal_employer_id);
    END IF;
    hr_utility.trace('~~~~ Start loop  p_period_start_date '||p_period_start_date);
    hr_utility.trace('~~~~ p_assignment_action_id '||p_assignment_action_id);
    FOR i IN get_prev_periods_dates( p_assignment_action_id, p_period_start_date) LOOP
        IF l_date = i.start_date AND l_amt <> 0 THEN
            NULL;
        ELSE
            l_amt := 0;
            IF l_date <> i.start_date THEN
                l_ctr := l_ctr + 1;
            END IF;
            l_amt := pay_balance_pkg.get_value (l_def_bal_id, i.assignment_action_id);
            IF l_amt <> 0 THEN
                l_cnt := l_cnt + 1;
            END IF;
            l_amount := l_amount + l_amt;
            hr_utility.trace('~~~~ Inside loop  start_date '||i.start_date);
            hr_utility.trace('~~~~ assignment_action_id '||i.assignment_action_id);
            hr_utility.trace('~~~~ l_ctr '||l_ctr);
            hr_utility.trace('~~~~ l_cnt '||l_cnt);
            hr_utility.trace('~~~~ l_amt '||l_amt);
            hr_utility.trace('~~~~ l_amount '||l_amount);
            hr_utility.trace('~~~~ p_no_month '||p_no_month);
            IF l_amt <> 0 OR p_flag = 'N' THEN
                p_days := p_days + last_day(i.start_date) - last_day(add_months(i.start_date,-1));
            END IF;
            IF l_ctr >= p_no_month THEN
                IF l_cnt = p_no_month OR p_flag = 'N' THEN
                    RETURN l_amount;
                /*ELSE
                    l_ctr := p_no_month - 1;*/
                END IF;
            END IF;
            l_date := i.start_date;
        END IF;
    END LOOP;
    hr_utility.trace('~~Exiting pay_es_ss_calculation.get_prev_salary');
    RETURN l_amount;
END get_prev_salary;
To get the previous month value -
Previous_Month_val = ES_GET_PREVIOUS_BALANCE('Gross','_ASG_PTD',Start_Date, 1, 'Y',' ',Work_Center_ch,num_days)
To get the previous 3 months value -
Previous_3_Month_val = ES_GET_PREVIOUS_BALANCE('Gross','_ASG_PTD',Start_Date, 3, 'Y',' ',Work_Center_ch,num_days)
Assignment_action_id is passed as a context to the formula function.
You need to tweak the code to suit your requirements.
Cheers,
Vigneswar
PS :
-- GET_DEFINED_BAL_ID
FUNCTION get_defined_bal_id(p_bal_name         IN  VARCHAR2
                           ,p_db_item_suffix   IN  VARCHAR2) RETURN NUMBER
IS
    CURSOR get_def_bal_id is
    SELECT pdb.defined_balance_id
    FROM   pay_balance_types pbt
          ,pay_balance_dimensions pbd
          ,pay_defined_balances pdb
    WHERE  pdb.balance_type_id = pbt.balance_type_id
    AND    pdb.balance_dimension_id = pbd.balance_dimension_id
    AND    pbt.balance_name = p_bal_name
    AND    pbd.database_item_suffix = p_db_item_suffix;
    l_def_bal_id NUMBER;
BEGIN
    OPEN get_def_bal_id;
    FETCH get_def_bal_id into l_def_bal_id;
    CLOSE get_def_bal_id;
    RETURN l_def_bal_id;
END get_defined_bal_id;