How to write function ??

Question

Dear All,
I wrote procedure for spliting the string.
But Now I want to write function that return the splitted value.
Here is my code for procedure.
DECLARE
  I NUMBER;
  J NUMBER;
  VAL VARCHAR2(100);
  VNEWSLETTERID VARCHAR2(100):='12,34,56,67,23,12,34,5,6,11,2,3,4,5,111,223,243,3453,45764,467,568568,58585';
BEGIN
  I := 1;
  J := 1;
WHILE INSTR(VNEWSLETTERID,',',I) != 0 LOOP
             VAL := SUBSTR(VNEWSLETTERID,I,INSTR(VNEWSLETTERID,',',I)-J);
             I := INSTR(VNEWSLETTERID,',',I)+1;
             J := I;
                --IND_TAB_PRIVS_DATA := IND_TAB_PRIVS(VAL);
             DBMS_OUTPUT.PUT_LINE(VAL);
END LOOP;
     VAL := SUBSTR(VNEWSLETTERID,I,LENGTH(VNEWSLETTERID));
     DBMS_OUTPUT.PUT_LINE(VAL);   
END;
Please hint me.
Thanks in advance,
Prathamesh.

Answer 1

PSP, I'm sure we've told you how to do this before....
Try this, it uses a pipelined function to return data as a table (can also be rewritten to output rows with multiple values if needed)...
SQL>   CREATE OR REPLACE TYPE split_tbl IS TABLE OF VARCHAR2(32767);
  2  /
Type created.
SQL>   CREATE OR REPLACE FUNCTION split (p_list VARCHAR2, p_delim VARCHAR2:=' ') RETURN SPLIT_TBL PIPELINED IS
  2      l_idx    PLS_INTEGER;
  3      l_list   VARCHAR2(32767) := p_list;
  4      l_value  VARCHAR2(32767);
  5    BEGIN
  6      LOOP
  7        l_idx := INSTR(l_list, p_delim);
  8        IF l_idx > 0 THEN
  9          PIPE ROW(SUBSTR(l_list, 1, l_idx-1));
10          l_list := SUBSTR(l_list, l_idx+LENGTH(p_delim));
11        ELSE
12          PIPE ROW(l_list);
13          EXIT;
14        END IF;
15      END LOOP;
16      RETURN;
17    END SPLIT;
18  /
Function created.
SQL> select * from table(split('1,2,3,4,5,6,7,8,9',','));
COLUMN_VALUE
1
2
3
4
5
6
7
8
9
9 rows selected.
SQL>There are various methods for splitting strings into rows including just SQL versions, but the above gives you an idea how you can turn a function into a table. It can be adapted to return a structured data type so that you get multiple values coming out per row as well.
;)