I can't seem to "close" my documents on MSoft Word with AppleScript!

Question

Hi
I have tons of documents open on MSoft Word and wish to close some of them. Luckily, those that I wish to close all start with the word "book", so I was thinking I could actually automate that with AppleScript hence avoid closing them one by one.
I wrote the following code:
tell application "Microsoft Word"
count (document)
          set countresult to result
          repeat with incrementValue from 1 to countresult
                    if name of document incrementValue starts with "book" then
  activate document
  close document
                    end if
          end repeat
end tell
To my surprise, it didn't work!
I got the following under "Replies", which showed that AppleScript did indeed try to close the document that starts with "book":
tell application "Microsoft Word"
count every document of current application
  --> 6
get name of document 1
  --> "book_mac_OS_X_and_iOS_internals.htm"
activate
close document
get name of document 2
  --> "applicable books.htm"
get name of document 3
  --> "What Do You Want Homespace to Do.htm"
get name of document 4
  --> "URL_repository_for_outcomes.htm"
get name of document 5
  --> "SYNTHESIS - History a Step Back.docx"
get name of document 6
  --> "SYNTHESIS - History a Step Back.docx"
end tell
But when I went back to Word, I still saw the document there!
I actually added an additional line (I didn't include the code in that which I pasted here) asking to count the number of documents in Word AFTER the so-called "close", and the number remains 6.
Can anyone enlighten me on this?
Regards,
junxiang99

Answer 1

Hi,
The quickest way to do this (tested with OS 10.8.2, MS Word 2011) is in one line:
tell application "Microsoft Word" to close every document whose name begins with "book"
The reason why your script doesn't work is that you aren't specifying to Word which document you want it to close.
So, changing one line ought to do it:
close document incrementvalue -- instead of "close document"
But... when you close a document, you change the document count. Document 2 becomes document 1, document 3 becomes document 2 etc. So eventually you'd get a message saying "The object you are trying to access doesn't exist".
Because of this, if you want to do it in a repeat loop, you have to work backwards:
tell application "Microsoft Word"
  set doc_count to count documents
  repeat with x from doc_count to 1 by -1
  if name of document x begins with "book" then close document x
  end repeat
end tell
Hope this helps.